APDL命令流挑战赛二——弹簧的参数化绘制

huright

希望大家积极参与。俺先献丑了。不同的人对模型和命令的掌握程度和理解程度不同，编写的代码也会有差异。把你的代码贴上来吧！！！

fini
/clear
/filn,spring
/title,helix
pi=3.1415926
R=4
r1=0.5
n=4
h=10
/prep7
csys,0
*do,t,0,1,0.01
xi=R*cos(t*(n*2*pi))
yi=R*sin(t*(n*2*pi))
zi=h*t
k,100*t+1,xi,yi,zi
*enddo
ksel,s,,,1,100,1
bspline,all
wpoff,kx(1),ky(1)
wprota,,-90,
csys,4
CYL4,0,0,0,,r1,360
csys,0
vdrag,1,,,,,,1
save,all
fini

huright

我想至少最初学者有帮助。

rodge

原帖由 huright 于 2007-5-23 15:09 发表

                               
登录/注册后可看大图

希望大家积极参与。俺先献丑了。不同的人对模型和命令的掌握程度和理解程度不同，编写的代码也会有差异。把你的代码贴上来吧！！！

根据你的命令流所建的弹簧存在一定的缺点，是不完整的，可以从图上比较看出
这是你的命令流所建的弹簧

rodge

下面这个是根据一些前辈得到的，我觉得是很经典的
fini
/clear,start
/filn,spring
/prep7
pi=acos(-1)
r0=2  
r1=10
p=6   
n=5 !
yd=10
zd=8/36
WPCSYS,-1,0
wpave,7,8,9-p*n/2
CSWPLA,11,1,1,1,
*do,i,1,36*n+1,1
k,i,r1,(i-1)*yd,(i-1)*zd
*enddo
bspl,all
KWPAVE,1
wpro,,90,
CYL4,,,r0
VDRAG,1,,,,,,1

huright

不是很明白你的意思？？
这只是联系，具体的弹簧的上下端面，可以参考有关资料，自己做。

rodge

原帖由 huright 于 2007-5-23 17:04 发表

                               
登录/注册后可看大图

不是很明白你的意思？？
这只是联系，具体的弹簧的上下端面，可以参考有关资料，自己做。

我的意思是你的上下端面能不能确保平齐呢？

huright

是一定要平齐吗？
俺不是很了解阿

rodge

这我也不太清楚，因为也没做过用弹簧计算的
不过，我想平齐总比不平齐要好，
既然有平齐的建模方式，当然就用好一点的啦

mengjigang

我做过螺纹的计算，建立螺纹用的就是那段经典的命令流，但是由于还要建立螺柱，然后再再粘接，就出现了一点问题，最后我的解决办法是建立多半圈螺纹，控制的角度大于180度就行，然后再裁减成平齐面，最后建立半螺柱，然后粘接，划分网格

yjm8384

高手把命令流中的参数给解释一下啊　　先谢谢了　　p=6   
n=5 !
　9-p*n/2

xuruikl

fini
/clear,start
/prep7
r=3
rs=0.3
n=20
s=1
pi=3.14159265
*do,i,1,n+6+3*n,1
x=r*cos((i-1)*2*pi/n)
y=r*sin((i-1)*2*pi/n)
z=(i-1)*s/n
k,i,x,y,z
*enddo
*do,i,1,n+1+3*n,5
bsplin,i,i+1,i+2,i+3,i+4,i+5
*enddo
lcomb,all
csys,4
wpro,,90
cyl4,kx(1),ky(1),rs,360
wpro,,-90
vdrag,1,,,,,,1
save,all
fini

rodge

关于之前我发的那个命令流，由于是直接拷贝过来，虽然也可以画出弹簧，但是确少了一部分，给大家带来的困挠表示抱歉，
因前面的贴子我无法修改，因此重新发一下，我经过修改过的命令流

之前引起误会的命令流作用主要是为了能够画任何角度的弹簧

fini
/clear,start
/filn,spring
/prep7
pi=acos(-1)
r0=2  !!!弹簧丝的半径
r1=10 !!!!弹簧的半径
n0=5 !!!!弹簧的圈数
n1=36 !!!!设置1圈弹簧分为36份
h=6   !!!!每圈弹簧的间距
yd=360/n1  
zd=h/n1   !!!!每个节点在Z方向的增量
WPCSYS,-1,0
wpave,7,8,9-h*n0/2   !!!!设置弹簧的中心坐标为(7,8,9)
wpro,,40,            !!!!设置弹簧的偏转角度
CSWPLA,11,1,1,1,
*do,i,1,n1*n0+1,1
k,i,r1,(i-1)*yd,(i-1)*zd
*enddo
bspl,all
KWPAVE,1
wpro,,90,
CYL4,,,r0
VDRAG,1,,,,,,1

xuruikl

rodge真是严谨啊
狂赞

mdj219

只能顶一下了啊!眼下写不出,再想想

dgc5112

我想其实也没什么，就是沿实际弹簧中心轴作一条曲线，在曲线一端作一个与曲线垂直的圆面，然后沿着曲线拉伸（Extrude）圆面即可，初学者按照这个思想做就行了。
欢迎高手批评指教:lol