ANSYS配筋板桥模型——板壳与配筋梁混合系统

xsdcaifu

此贴与原文相比少一部分，原文见
http://ningxy.bokee.com/viewdiary.12032706.html

如图8-6、图8-7、图8-8示，由0.1*0.1*0.01（m）方形截面型钢焊接成四边形外框，在横向等间距设置两条纵向L形截面型钢L0.1*0.12*0.01（m），四边形外框尺寸12*3（m）。一块尺寸为12*3（m）厚度为0.01（m）的钢板焊接到型钢框架上，所有型钢与面板接触面全部采用连续焊缝。钢板弹模2*10**11（Pa），波松比0.3，型钢弹模2.1*10**11，波松比0.3。型钢框架一侧的两个角点为铰支座，另一侧的两个角点为可滑动支座（仅约束Z向的位移）。面板上作用250pa的均布荷载，计算结构的应力分布与最大应力，确定型钢受的弯距和轴力。


模型建好后要调整单元的相对位置。

    1.修改所有方钢管梁单元的位置：默认的位置如图8-9所示截面库中方形截面，缺省时该截面的单元坐标系原点位置在左下角，要调整到图8-8所示的位置。需要将直线（划分当前梁单元的线）定位到单元坐标系的坐标（x，z）上，y=0；z=0.1+0.01/2。

    2.通过颠倒3号线的方向来颠倒其上L型截面的y的方向，3号线上的梁单元L的侧向板与实际需要的方向相反，即需要调整3号线的方向来调整梁单元的x轴方向，而z轴方向不变（方向关键点确定的），那么程序自动改变y轴的指向，即达到颠倒L截面侧向板指向。颠倒3号线方向的方法：main menu >preprocessor>modeling >move/modify>reverse>of lines,

弹出对话框拾取3号线，单击OK，再单击OK。

    3.同1. 修改L型角钢的梁单元相对位置，offset-y=0;   offset-z=0.1-0.01/2+0.01/2=0.1

    4.颠倒面与壳单元的法向方向：首先打开面的法向箭头符号，plotctrls>symbols (我的8.0版本找不到次项) ，对应的命令 /psymb，adir，1 ；/replot。接着 执行命令aplot；然后main menu >preprocessor>modeling >move/modify>reverse>of areas,弹出对话框拾取所有的面“pick all”，单击OK，再单击OK。最后再执行命令aplot，比较法向的变化。

/FILNAME,shell-beam,1
/TITLE,the shell and beam modle
/PREP7
ET,1,SHELL93
ET,2,BEAM189   !189有四个节点
R,1,0.01

SECTYPE,1,BEAM,HREC,fgg,0   !定义截面为方钢管
SECOFFSET,CENT
SECDATA,0.1,0.1,0.01,0.01,0.01,0.01
SECTYPE,2,BEAM,L,jg,0       !定义截面为L型角钢
SECOFFSET,CENT
SECDATA,0.12,0.1,0.01,0.01

MP,EX,1,2e11   
MP,PRXY,1,0.3   
MP,EX,2,2.1e11
MP,PRXY,2,0.3  

k,1,0,0,0                   !创建12个关键点，其中9，10，11，12为方向关键点
k,2,0,1,0
k,3,0,2,0
k,4,0,3,0
k,5,12,0,0
k,6,12,1,0
k,7,12,2,0
k,8,12,3,0
k,9,0,0,1
k,10,0,1,1
k,11,0,2,1
k,12,12,3,1

a,1,5,6,2                  !创建三个面
a,2,6,7,3
a,3,7,8,4

/PNUM,KP,1  
/PNUM,LINE,1
/REPLOT
GPLOT                      !显示所有的

LSEL,S,,,1,10,3
LATT,2,1,2,,9,,1  !LATT, MAT, REAL, TYPE, --, KB, KE, SECNUM，这里KB, KE分别为起、终方向关键点
LSEL,S,,,2,8,3
lsel,a,,,9
LATT,2,1,2,,12,,1
lsel,s,,,3
LATT,2,1,2,,10,,2
lsel,s,,,6
LATT,2,1,2,,11,,2
allsel,all
LESIZE,all,0.5
LMESH,all
/ESHAPE,1.0       !显示截面
/REPLOT

AATT,1,1,1,0
AESIZE,all,0.5
amesh,all

SECTYPE,1,BEAM,HREC,fgg,0        !改变梁单元相对位置
SECOFFSET,USER,0,0.105   
SECDATA,0.1,0.1,0.01,0.01,0.01,0.01
/REPLOT

SECTYPE,2,BEAM,L,jg,0         !改变梁单元相对位置   
SECOFFSET,USER,0.0,0.1   
SECDATA,0.12,0.1,0.01,0.01  
/REPLOT

LREVERSE,3   !LREVERSE, LNUM, NOEFLIP，改变三号线的方向

/psymb,adir,1    !显示面的法向符号  
/replot
aplot

AREVERSE,ALL     !改变面的法向方向
/REPLOT
save
finish

/SOL
ANTYPE,0
ksel,s,,,1,4,3
DK,all, , , ,0,UX,UY,UZ
ksel,s,,,5,8,3
DK,all, , , ,0,,,UZ
SFA,all,1,PRES,250
ALLSEL
solve
FINISH  
/POST1  

!省略

sysh320

我感觉不要只是粘贴别人的东东
能不能加入自己的理解和看法，否则就给一个网址就可以了
不要为了发贴而发贴