焊接生死单元例子

gongqing

/TITLE,weld
/PREP7
/UNIT,SI
ET,1,13,4
ET,2,13,4

MPTEMP,1,20,500,1000,1500,2000
MPDATA,EX,1,1,1.93e11,1.5e11,0.7e11,0.1e11,0.01e11
MPDATA,EX,2,1,1.02e11,0.5e11,0.08e11,0.001e11,0.0001e11
MPDATA,EX,3,1,1.17e11,0.9e11,0.3e11,0.05e11,0.005e11

TB,BKIN,1,5
TBTEMP,20,1
TBDATA,1,1200E6,0.193E11
TBTEMP,500,2
TBDATA,1,933E6,0.150E11
TBTEMP,1000,3
TBDATA,1,435E6,0.070E11
TBTEMP,1500,4
TBDATA,1,70E6,0.010E11
TBTEMP,2000,5
TBDATA,1,7E6,0.001E11

TB,BKIN,2,5
TBTEMP,20,1
TBDATA,1,800E6,0.102E11
TBTEMP,500,2
TBDATA,1,400E6,0.050E11
TBTEMP,1000,3
TBDATA,1,70E6,0.008E11
TBTEMP,1500,4
TBDATA,1,1E6,0.00010E11
TBTEMP,2000,5
TBDATA,1,0.1E6,0.00001E11

TB,BKIN,3,5
TBTEMP,20,1
TBDATA,1,900E6,0.117E11
TBTEMP,500,2
TBDATA,1,700E6,0.090E11
TBTEMP,1000,3
TBDATA,1,230E6,0.030E11
TBTEMP,1500,4
TBDATA,1,40E6,0.005E11
TBTEMP,2000,5
TBDATA,1,4E6,0.0005E11

MP,DENS,1,8030
MP,DENS,2,4850
MP,DENS,3,8900

MP,ALPX,1,1.78E-5
MP,ALPX,2,9.36E-5
MP,ALPX,3,1.66E-5

MP,NUXY,1,0.29
MP,NUXY,2,0.30
MP,NUXY,3,0.30

MP,KXX,1,16.3
MP,KXX,2,7.44
MP,KXX,3,393

MP,C,1,502
MP,C,2,544
MP,C,3,385

MP,MURX,1,1
MP,MURX,2,1
MP,MURX,3,1

MP,REFT,1,20
MP,REFT,2,1500
MP,REFT,3,20

CSYS,0
K,1,0,0,0
K,2,0.5,0,0
K,3,1,0,0,0
K,4,0,0.3,0
K,5,0.35,0.3,0
K,6,0.65,0.3,0
K,7,1,0.3,0
A,1,2,5,4
A,2,6,5
A,2,3,7,6

ESIZE,0.025
TYPE,2
MAT,2
AMESH,2
ESIZE,0.05
TYPE,1
MAT,1
AMESH,1
MAT,3
AMESH,3
EPLOT

/SOLU
ANTYPE,4
TRNOPT,FULL

NSEL,ALL
*GET,MINX,NODE,,MNLOC,X
NSEL,S,LOC,X,MINX
D,ALL,UX,0
*GET,MINY,NODE,,MNLOC,Y
NSEL,S,LOC,Y,MINY
D,ALL,UY,0

NSEL,ALL
*GET,MINX,NODE,,MNLOC,X
NSEL,S,LOC,X,MINX
D,ALL,TEMP,20
NSEL,ALL
*GET,MAXX,NODE,,MXLOC,X
NSEL,S,LOC,X,MAXX
D,ALL,TEMP,20

NNA=2
ESEL,ALL
*GET,EMAX,ELEM,,NUM,MAX
ASEL,S,AREA,,NNA
ESLA
*GET,NSE,ELEM,,COUNT
*DIM,NE,,NSE
*DIM,NEX,,NSE
*DIM,NEY,,NSE
*DIM,NEORDER,,NSE

MINE=0
*DO,I1,1,NSE
ESEL,U,ELEM,,MINE
*GET,NSE1,ELEM,,COUNT
II=0
*DO,I,1,EMAX
*IF,ESEL(I),EQ,1,THEN
II=II+1
NE(II)=I
*ENDIF
*ENDDO

*DO,I,1,NSE1
*GET,NEY(I),ELEM,NE(I),CENT,Y
*GET,NEX(I),ELEM,NE(I),CENT,X
*ENDDO

MINY=1E20
MINX=1E20

*DO,I,1,NSE1
*IF,NEY(I),LT,MINY,THEN
MINY=NEY(I)
MINX=NEX(I)
MINE=NE(I)
*ELSE
*IF,NEY(I),EQ,MINY,THEN
*IF,NEX(I),LT,MINX,THEN
MINY=NEY(I)
MINX=NEX(I)
MINE=NE(I)
*ENDIF
*ENDIF
*ENDIF
*ENDDO
NEORDER(I1)=MINE
*ENDDO


MAX_TEM=1500
DT1=1E-3
DT=5                    
T=0
ESEL,ALL
EPLOT
/AUTO,1
/REPLOT
*DO,I,1,NSE
EKILL,NEORDER(I)
ESEL,S,LIVE
EPLOT
*ENDDO
ALLSEL,ALL
OUTRES,ALL,ALL
IC,ALL,TEMP,20
KBC,1
TIMINT,0,STRUCT
TIMINT,1,THERM
TIMINT,0,MAG
TINTP,0.005,,,1,0.5,0.2


NSUB1=2
NSUB2=40
*DO,I,1,NSE
EALIVE,NEORDER(I)
ESEL,S,LIVE
EPLOT
ESEL,ALL

T=T+DT1
TIME,T
NSUBST,1
*DO,J,1,4
D,NELEM(NEORDER(I),J),TEMP,MAX_TEM
*ENDDO
SOLVE

T=T+DT1
TIME,T
SOLVE

*DO,J,1,4
DDELE,NELEM(NEORDER(I),J),TEMP
*ENDDO
T=T+DT-2*DT1
TIME,T
NSUBST,NSUB1
SOLVE
*ENDDO
T=T+50000
TIME,T
NSUBST,NSUB2
SOLVE
FINISH




/POST1

/SEG,DELE
/CONT,1,15,0,1200E6/16,1200E6
/DSCALE,1,1.0
AVPRIN,0,0
AVRES,1
/SEG,MULTI,STRESS,0.1
ESEL,ALL
*DO,I,1,NSE
ESEL,U,ELEM,,NEORDER(I)
*ENDDO
*DO,I,1,NSE
ESEL,A,ELEM,,NEORDER(I)
SET,(I-1)*3+1,1
PLNSOL,S,EQV
*DO,J,1,NSUB1
SET,(I-1)*3+3,J
PLNSOL,S,EQV
*ENDDO
*ENDDO
*DO,I,1,NSUB2
SET,(NSE-1)*3+4,I
PLNSOL,S,EQV
*ENDDO
/SEG,OFF,STRESS,0.1
/ANFILE,SAVE,STRESS,AVI

marijuana

这个是错的吧！我做了N次了！ 都说运行错误！

lixiaoyu0323

谢谢！:@D
仔细看看，多少能学点东西

mada

仔细看，热传导系数错了，应该是3.93，少了个小数点