个人练习：正弦函数加载

zongzhou

个人练习：正弦函数加载
FINISH
/CLEAR,START

/TITLE,THE APPLICATION OF SIN FUNCTION
*AFUN,DEG

!0.参数定义与赋值
R=10 $ R0=12.5 $ L=3 !圆弧的半径和纵长
THETA0=30 $ THETA1=120 !圆弧的起始、结束角
THETA0_G=Theta0/180*3.14 $ THETA1_G=Theta1/180*3.14 !圆弧的起始、结束弧度
F=1000 !压力载荷
P0=2*F/(R*L)/((Theta1_G-Theta0_G)-(SIN(Theta1)*COS(Theta1)-SIN(Theta0)*COS(Theta0))) !正弦分布压力幅值


/PREP7
!1.几何模型
CYLIND,R,R0,0,L,THETA0,THETA1

!2.有限单元模型
ET,1,SOLID186
MP,EX,1,2.1E11
MP,NUXY,1,0.3

VSWEEP,1

FINISH

/SOLU
!3.计算模型
!1)分析类型
ANTYPE,STATIC
OUTRES,ALL,ALL

!2)约束条件
CSYS,1
ASEL,S,LOC,Y,THETA0 $ ASEL,A,LOC,Y,THETA1
DA,ALL,ALL

!3)载荷条件
!<1>正弦压力分布函数表
FUNNAME='TSIN' $ FUNCSYS=1 !函数表格名和函数坐标系
*DIM,FUNVALUE,,1 $ FUNVALUE(1)=P0 !函数数组及其赋值
*DIM,%FUNNAME%,TABLE,6,3,1,,,,%FUNCSYS% !函数表格类型数组
!Begin of equation: P0*sin({Y})
%FUNNAME%(0,0,1)=0,-999,0,%FUNVALUE(1)%,0,0,0
%FUNNAME%(0,1,1)=1,-1,9,1,3,0,0
%FUNNAME%(0,2,1)=0,-2,0,1,17,3,-1
%FUNNAME%(0,3,1)=1,99,0,1,-2,0,0
!End of equation: P0*sin({Y})
   
!<2>施加正弦分布压力
SFA,4,1,PRES,%TSIN%

!4)计算求解
ALLSEL,ALL
SOLVE

FINISH

sysh320

这个提议很好的，希望楼主继续
就自己的见解感受也发过来，这样更好了

djaity

不错，鼎

pengmanhua

好主意