斜拉桥三维仿真分析【转】

Chelsea

1. 
   
2. /filname,cable-stayed bridge,1
   
3. keyw,pr_struc,1
   
4. /prep7
   
5. !定义单元类型
   
6. et,1,beam4
   
7. et,2,link10
   
8. !定义材料属性
   
9. mp,ex,1,3.5e10
   
10. mp,prxy,1,0.17
    
11. mp,dens,1,2500
    
12. mp,ex,2,10e15
    
13. mp,prxy,2,0
    
14. mp,dens,2,0
    
15. mp,ex,3,1.9e10
    
16. mp,prxy,3,0.25
    
17. mp,dens,3,1200
    
18. mp,damp,3,0.5
    
19. !定义实常数
    
20. !定义实常数
    
21. r,1,25.6,5.546.133,16,1.6
    
22. r,2,16,29.417,15.394,3.4,4.7
    
23. r,3,54,364.5,162,6,9
    
24. r,4,40,213.3,83.3,5,8
    
25. r,5,1,1/12,1/12,1,1
    
26. r,6,0.012,0.012             !索的
    
27. 
    
28. !创建节点和单元
    
29. !建立主梁节点
    
30. /view,1,1,1,1
    
31. /angle,1,270,xm,0
    
32. /replot
    
33. 
    
34. *do,i,1,59           !此循环用于建立主梁的半跨节点
    
35. x=-174*2+(i-1)*6     !最左端x=174*2，x=0左边的节点x坐标值，间距为6
    
36. y1=-14               !桥面宽28米，故左边节点为-14
    
37. y2=14                !桥面宽28米，故右边节点为-14
    
38. n,3*(i-1)+1,x        !建立主梁节点              3*（i-1）+1为节点号
    
39. n,3*(i-1)+2,x,y1     !以下两行建立桥面两边节点
    
40. n,3*i,x,y2           !能想出这种建模命令的绝对是编程高手，哈哈
    
41. *enddo               !完全可以先建立端部的三个节点，然后用这三个节点在x方向上复制59份，间距为6
    
42. !建立主梁单元
    
43. type,1
    
44. real,1
    
45. mat,1
    
46. *do,i,1,58,1         !以下循环建立建立桥面中线主梁单元
    
47. j=3*(i-1)+1
    
48. e,j,j+3
    
49. *enddo
    
50. !建立鱼刺刚横梁
    
51. type,1
    
52. real,5
    
53. mat,2
    
54. *do,i,1,59,1         !以下循环用于建立桥面鱼刺横梁的节点
    
55. j=3*(i-1)+1
    
56. j1=3*(i-1)+2
    
57. j2=3*i
    
58. e,j,j1
    
59. e,j,j2
    
60. *enddo
    
61. !建立半跨主塔
    
62. i=59*3            !变量用于记录桥面的节点数，即至此已经建立了59*3个节点了，用于指导以后设定节点的编号
    
63. n,i+1,-174,-10,-30   !以下两行记录塔脚节点
    
64. n,i+2,-174,10,-30
    
65. n,i+3,-174,-15   !以下两行用于建立与桥面齐高的主塔节点
    
66. n,i+4,-174,15
    
67. *do,j,1,5,1      !以下循环用于建立索塔在桥面以上的节点
    
68. k=i+4+j
    
69. n,k,-174,0,60+(j-1)*18
    
70. *enddo
    
71. !建立下索塔单元
    
72. type,1
    
73. real,4
    
74. mat,1
    
75. e,i+1,i+3          !以下用于建立主塔在桥面以下的两根塔柱单元
    
76. e,i+2,i+4
    
77. !建立中索塔单元
    
78. type,1
    
79. real,3
    
80. mat,1
    
81. e,i+3,i+5            !以下用于建立倒Y分叉点到桥面间的两根塔柱单元
    
82. e,i+4,i+5
    
83. !建立上索塔单元
    
84. type,1
    
85. real,2
    
86. mat,1
    
87. *do,j,1,4,1          !以下用于建立倒Y分叉点以上的塔柱单元
    
88. k=i+4+j
    
89. e,k,k+1
    
90. *enddo
    
91. !建立与塔的倒Y分叉点链接的索单元
    
92. type,2
    
93. real,6
    
94. mat,3
    
95. e,i+5,89
    
96. e,i+5,90
    
97. !建立主塔倒Y分叉点以上第一个张拉点连接的索单元
    
98. *do,j,1,8,1
    
99. !此循环用于建立主塔倒Y分叉点以上第一个张拉点连接的所有索单元，共32个
    
100. e,i+6,89+3*j
     
101. e,i+6,89-3*j
     
102. e,i+6,90+3*j
     
103. e,i+6,90-3*j
     
104. *enddo
     
105. !建立与主塔的其他三个张拉点连接的单元
     
106. *do,k,1,3,1
     
107. *do,j,1,7,1
     
108. e,i+6+k,113+(k-1)*21+3*j      !一共有28个索单元连接在每个张拉点上
     
109. e,i+6+k,65-(k-1)*21-3*j
     
110. e,i+6+k,114+(k-1)*21+3*j
     
111. e,i+6+k,66-(k-1)*21-3*j
     
112. *enddo
     
113. *enddo
     
114. !生成全桥模型节点
     
115. i=i+9                         !记录半跨的所有节点数
     
116. nsym,x,i,all                  !用映射法直接建立另半跨节点
     
117. esym,,i,all                   !用映射法直接建立另半跨单元
     
118. nummrg,all                    !合并所有节点和单元
     
119. !建立索塔连接横梁单元
     
120. type,1
     
121. real,5
     
122. mat,2
     
123. j=i
     
124. i=i-9
     
125. n,1000,-174
     
126. e,1000,i+3
     
127. e,1000,i+4
     
128. n,2000,174
     
129. e,2000,i+3+j
     
130. e,2000,i+4+j
     
131. !施加主塔的四个脚上的全约束
     
132. nsel,s,loc,z,-30
     
133. d,all,all
     
134. allsel
     
135. !在左桥端施加y,z约束
     
136. nsel,s,loc,x,-348         !仅给左端主梁施加约束
     
137. nsel,r,loc,y,0
     
138. d,all,uy
     
139. d,all,uz
     
140. allsel
     
141. 
     
142. !在右桥端施加y约束
     
143. nsel,s,loc,x,348         !仅给右端主梁施加约束
     
144. nsel,r,loc,y,0
     
145. d,all,uy
     
146. allsel
     
147. 
     
148. numcmp,all
     
149. !施加重力场
     
150. acel,,,9.8
     
151. 
     
152. !耦合节点,耦合跨中由于对称而重复的单元节点以及两主塔上塔横梁和主梁的重合节点，
     
153. cpintf,uy
     
154. cpintf,uz
     
155. cpintf,rotx
     
156. cpintf,rotz
     
157. 
     
158. !成桥状态的确定
     
159. !静力的初步计算
     
160. !直接进行静力计算
     
161. /solu
     
162. solve
     
163. finish
     
164. !得到最大位移为1.288m，由于偏差太大需要重新计算（与事实不符）
     
165. !修改实常数后重新计算：令r,6,0.012,0.012,即给索以预应变0.012
     
166. /solu      !为了将计算应力用于下面的动力分析，这里打开预应力和集中质量设置开关
     
167. lumpm,on
     
168. pstres,on
     
169. solve
     
170. finish
     
171. !求得最大位移为0.0329m，说明已经达到成桥状态要求,(与事实不符)
     
172. 
     
173. 
     
174. !模态分析
     
175. !分析设置
     
176. /solu
     
177. antype,2
     
178. !MODOPT,LANB,20  
     
179. !EQSLV,SPAR  
     
180. MXPAND,10, , ,0
     
181. LUMPM,1
     
182. PSTRES,1
     
183. 
     
184. MODOPT,LANB,20,0,100, ,OFF
     
185. UPCOORD,1,ON              !更新模型计算坐标，目的是为了将预应力效应准确的应用能够到模态分析上来
     
186. !分析设置完毕
     
187. solve
     
188. finish
     
189. !激励耦合分析
     
190. !恢复成桥静力计算结果
     
191. RESUME, cable-stayedbridge,db, !路径：utility menu>file>resume jobname.db
     
192. !生成地震激励向量，将记事本格式的地震波数据调入到工作目录下,并执行以下命令
     
193. 
     
194. *DIM,aay1,ARRAY,2,50,1
     
195. 
     
196. *DIM,aaz1,ARRAY,2,50,1  
     
197.   
     
198. *CREATE,ansuitmp
     
199. *VREAD,aay1(1,1),'tjx','txt',' ',50
     
200. (e9.3,e11.3)
     
201. *END
     
202. /INPUT,ansuitmp
     
203. 
     
204. *CREATE,ansuitmp
     
205. *VREAD,aaz1(1,1),'tjy','txt',' ',50
     
206. (e9.3,e11.3)
     
207. *END
     
208. /INPUT,ansuitmp
     
209. 
     
210. !输入车辆激励波，Z=1000*cos(10*t).车子跨越一个单元的时间为0.1秒（速度216公里/小时），全桥共696米，历时11.6秒，纵向共116个单元，117个节点
     
211. n=117                             !定义向量维数
     
212. *dim,fcar,array,n                 !定义车载荷向量
     
213. *do,i,1,n,1                       !以下循环为生成车载荷数据，即向“farc”矩阵中写入数据
     
214. tt=(i-1)*0.1
     
215. fcar(i)=1000*cos(10*tt)
     
216. *enddo
     
217. 
     
218. !输入风载荷激励p=50*sin(1.5*t)。由于梁长6米，高3米，故每个节点的受力可表示为：
     
219. 
     
220. *dim,fwind,array,n,n        !定义风荷载向量，***注意要与车辆荷载步即时间相等***
     
221. *do,i,1,n,1
     
222. tt=(i-1)*0.1                 !按不同时刻，每一次都是给列赋值，即各节点赋予荷载值，第a行第b列表示第b时刻第a个节点的荷载值
     
223. p=50*sin(1.5*tt)
     
224. fwind(1,i)=3*3*p    !两端的每根梁的面积为6*3，两个节点上所受的力应为一半面积与压力的乘积：3*3*p
     
225. *do,j,1,n-2
     
226. fwind(j+1,i)=6*3*p  !中间的每根梁的面积为6*3，两个节点上所受的力应为两个相邻梁各一半面积与压力的乘积：6*3*p
     
227. *enddo
     
228. fwind(n,i)=3*3*p
     
229. *enddo
     
230. 
     
231. 
     
232. !加载步耦合
     
233. !由于瞬态分析是以荷载步为阶段来求解的，所以应该将117个载荷步分别写入荷载文件中
     
234. finish          !完成上一阶段的设置
     
235. /config,nres,2000    !设置最大子步数为2000
     
236. /solu
     
237. antype,trans      !定义分析类型为瞬态
     
238. trnopt,full       !求解方式为完全法
     
239. m=n               !m变量表示向量的需要存储的时间点数  m=n=117
     
240. 
     
241. *do,i,1,m,1       !总循环开始，开始激励的耦合循环
     
242. time,i*0.1        !给每个载荷步文件设置结束点时间
     
243. auto,off          !关闭自动时间步选项
     
244. deltim,0.05       !设置子步求解的时间间隔
     
245. kbc,0             !选择ramped选项
     
246. outres,basic      !选择基本结果输出
     
247. cnvtol,f,,0.01   !选择力收敛准则，容差为0.01
     
248. !施加地震激励
     
249.     *if,i,le,50,then       !如果i小于等于50（le为little equal to）
     
250.     acel,,-aay1(2,i),10-aaz1(2,i)   !其中最后一项 为重力加速度与地震竖向加速度的差值
     
251.     *else
     
252.     acel,0,0,10
     
253.     *endif
     
254. !施加移动载荷激励
     
255. *if,i,eq,1,then     !如果力作用在最左端的主梁上时，单独定义施加的载荷，目的为了以下删除载荷的语句可以使用
     
256. nsel,s,loc,x,-174*2
     
257. nsel,r,loc,y,0
     
258. nsel,r,loc,z,0
     
259. f,all,fz,-fcar(i)
     
260. allsel
     
261. *else               !如果力不是作用在最左端时
     
262. nsel,s,loc,x,-174*2+i*6           !选择受力节点施加载荷
     
263. nsel,r,loc,y,0
     
264. nsel,r,loc,z,0
     
265. f,all,fz,-fcar(i)
     
266. allsel
     
267. nsel,s,loc,x,-174*2+(i-1)*6       !删除前一节点上的载荷
     
268. nsel,r,loc,y,0
     
269. nsel,r,loc,z,0
     
270. fdele,all,fz
     
271. allsel
     
272. *endif
     
273. 
     
274. !施加风载荷,（子循环）
     
275.   *do,j,1,m,1
     
276.   nsel,s,loc,y,-14           !选择有风作用一侧的节点
     
277.   nsel,r,loc,x,-174*2+(j-1)*6
     
278.   f,all,fy,fwind(j,i)        !给所选节点施加载荷
     
279.   allsel
     
280.   *enddo
     
281. lswrite,i                    !写数据到载荷步文件i
     
282. *enddo        !总循环结束
     
283. lssolve,1,m,1
     
284. 
     

复制代码

zzczzx

楼主很厉害。斜拉悬索、连续钢构都做得来，学习了。