大质量法做地震行波效应输入的问题
我想问一下，请问坛内有没有哪位仁兄做过大质量法的输入。我最近在做大质量法的东西，出现一个问题，就是要是不考虑行波效应的话，用大质量法做一致输入和直接用acel命令计算时得到的结果完全一致，但是考虑行波效应之后算出的不管是位移还是内力都往一个方向飘，不能出现地震波应有的振动，请问这是什么原因呢，谢谢各位关注了， 这个问题已经困扰我很长时间，希望各位能给予解答，谢谢各位关注了，本人不胜感激···· {:{39}:}回答一下吧{:{19}:}谢谢了 一个方向振荡才对啊 行波效应的例子，三根梁的平面刚架，两个固定基础。1）不考虑行波效应，约束基础，在全结构上施加加速度时程，
2）是不考虑行波效应，按照大质量法，在基础上施加同样加速度时程，得到的结果与1）在全结构施加加速度是一样的。
3）考虑行波效应，大质量法，两个基础上作用不一样的加速度历程。
1）
!x方向基础加速度，两脚固定刚架，无行波效应的命令流
/UNITS,SI
/PREP7
ET,1,Beam3
MP,EX,1,210E9
MP,PRXY,1,0.3
MP,DENS,1,7800
R,1,3E-4,2.5E-9,0.01
N,1,0,0,0
N,2,10,0,0
N,3,20,0,0
N,4,0,-10,0
N,5,20,-10,0
E,1,2
E,2,3
E,4,1
E,5,3
D,4,all,
D,5,all,
dmprat,0.02
EPLOT
/solu
*dim,baseacel,array,500 ! 定义正弦波的“基础加速度”, 500时间点
*do,i,1,500
baseacel(i)=0.1*sin(i*0.2) !
*enddo
NSUBST,1, , ,1 !1个子步
OUTRES,ALL,1 !输出每个子步的结果
ANTYPE,TRANS !时程分析
*do,i,1,500
acel,baseacel(i),0,0
TIME,i*0.1
solve
*enddo
/POST26
NSOL,2,2,U,x,Ux-at-2
PLVAR,2 !plot displacement time history
deriv,3,2,1,,v2 ! v=dy/dt
deriv,4,3,1,,a2 ! a=dv/dt
!QUOT,9,2,10, , , , ,1,1,
!plvar,9
/wait,3
plvar,2,3,4 ! ! plot disp., velocity and acceleration history together
fini
/eof
2）
!x方向基础加速度，两脚固定刚架，
/UNITS,SI
/PREP7
ET,1,Beam3
MP,EX,1,210E9
MP,PRXY,1,0.3
MP,DENS,1,7800
R,1,3E-4,2.5E-9,0.01
N,1,0,0,0
N,2,10,0,0
N,3,20,0,0
N,4,0,-10,0
N,5,20,-10,0
E,1,2
E,2,3
E,4,1
E,5,3
D,4,all,
D,5,all,
EPLOT
!!!!Add large mass!!!
ET,2,MASS21
KEYOPT,2,3,4 ! 2D without rotational inertial
R,2,1e5,1e5,1e5,1e5,1e5,1e5,
type,2
real,2
mat,1
e,4
e,5
DDELE,4,UX ! 去掉基础上待施加加速度方向的约束
ddele,5,ux
dmprat,0.02 ! 全结构阻尼比0.02
FINISH
/solu
*dim,baseacel,array,500 ! 定义正弦波的“基础加速度”, 500时间点
*do,i,1,500
baseacel(i)=0.1*sin(i*0.2) !
*enddo
NSUBST,1, , ,1 !1个子步
OUTRES,ALL,1 !输出每个子步的结果
ANTYPE,TRANS !时程分析
*do,i,1,500
f,4,fx,1e5*baseacel(i) ! F=m*a
f,5,fx,1e5*baseacel(i) ! 两基础上同步施加一样的加速度，等于没有行波效应
TIME,i*0.1
solve
*enddo
/POST26
NSOL,2,2,U,x,Ux-at-2 ! 2节点的绝对位移，不正确
PLVAR,2 !plot displacement time history
NSOL,5,5,U,x,Ux-at-2 ! 基础的绝对位移
ADD,8,2,5, , , , ,1,-1,1, ! 2节点位移与基础位移相减得到相对位移
plvar,8
deriv,3,8,1,,v2 ! v=dy/dt
deriv,4,3,1,,a2 ! a=dv/dt
/wait,3
plvar,3,4,8 ! ! plot disp., velocity and acceleration history together
fini
/eof
3）
!x方向基础加速度，两脚固定刚架，有行波效应的命令流
!前面语句与上一个例子一样，
/solu
*dim,baseace1,array,500 ! 定义正弦波的“基础加速度”, 500时间点
*dim,baseace2,array,500
*do,i,1,500
baseace1(i)=0.1*sin(i*0.2) !
baseace2(i)=0.1*sin(i*0.2-0.4) !
*enddo
NSUBST,1, , ,1 !1个子步
OUTRES,ALL,1 !输出每个子步的结果
ANTYPE,TRANS !时程分析
*do,i,1,500
f,4,fx,1e5*baseace1(i) ! F=m*a
f,5,fx,1e5*baseace2(i) ! 第二个基础加速度比第一个相位滞后0.4,模拟一种行波效应
TIME,i*0.1
solve
*enddo
/POST26
NSOL,2,2,U,x,Ux-at-2 ! 2节点的绝对位移，不正确
PLVAR,2 !plot displacement time history
NSOL,5,5,U,x,Ux-at-2 ! 基础的绝对位移
ADD,8,2,5, , , , ,1,-1,1, ! 2节点位移与基础位移相减得到相对位移
plvar,8
deriv,3,8,1,,v2 ! v=dy/dt
deriv,4,3,1,,a2 ! a=dv/dt
/wait,3
plvar,3,4,8 ! ! plot disp., velocity and acceleration history together
fini
/eof
谢谢Chelsea的帮忙，我争取从中有所参悟······ 回复 4 # Chelsea 的帖子
谢谢Chelsea的帮忙，我争取从中有所参悟······ 谢谢各位的意见，很受启发啊 请问对土坝这种连续的基础，如何使用大质量法输入考虑行波的地震作用呢？毕竟对于桥梁这样的离散基础，每个桥墩给一个大质量就可以了，但是土坝是连续基础，如何使一个大质量仅仅控制几个节点而不影响另外的节点呢？而且相邻节点加速度的值肯定不能相差太大 我曾经做过一点这方面的东西，我刚开始算出来的结果也同楼主说的一样，是往一个方向飘的，后来慢慢才发现，主要是由于两种加载方式所取的坐标系是不同的。直接用acel命令时，加的是惯性力，它算出来的位移是以地面为参考坐标的，而用大质量法时，参考坐标取的是空间的某一点，算出来的位移是加上地面运动位移后的结果，所以会有差别，最好是能找一个固定的参考点，用总位移减去这个参考点的位移，这样得到的结果就差不多了。 Chelsea 发表于 2011-1-10 10:27 static/image/common/back.gif
行波效应的例子，三根梁的平面刚架，两个固定基础。
1）不考虑行波效应，约束基础，在全结构上施加加速度 ...
你好，我是在不同的底座上加载了不同的力的时程，因此结果是每个底座的位移也不一样，可是大质量法中说是要减去底座的位移，像这样的情况应该如何选取位移呢? mwyfitfk 发表于 2013-1-14 17:14
你好，我是在不同的底座上加载了不同的力的时程，因此结果是每个底座的位移也不一样，可是大质量法中说是 ...
这种情况下是没有具体格式的，只是说是个相对位移，取不同的支座做参照点就会有不同的相对位移。 Chelsea 发表于 2011-1-10 10:27
行波效应的例子，三根梁的平面刚架，两个固定基础。
1）不考虑行波效应，约束基础，在全结构上施加加速度 ...
如果考虑刚架的自重，怎么办？即竖向还要考虑自重。去掉约束后支座反力怎么办？我的模型算出来的结果不对。
页:
[1]