[求助]直线电机建模实例哪里有？
请高手帮忙！回复：（student）[求助]直线电机建模实例哪里有？
一个例子<BR><BR><PRE>!基本参数a=0
move=0 !磁极移动的距离
gj=0 !初相角
Is=100*1.4142 !定子电流幅值
Ns=1 !定子绕组匝数
Brt=32/1000 !转子齿宽
Brs=11/1000 !转子槽宽
Brb=13.25/1000 !磁极边缘宽
Hg=58.5/1000 !转子拱高
Hg1=45.5/1000 !转子拱高1
Hrg=10/1000 !气隙长度
T=266.5/1000 !极距
Tr=166.5/1000 !磁极宽
Tg=50/1000 !线圈和间隙宽之和
Brg=56.5/1000 !转子拱宽
Brj=55/1000 !转子轭宽
Brx=45.25/1000 !励磁线圈宽45.25*2+166.5+2*2(环氧树脂)+5.5(磁极间隙)=266.5
Bg=(Tg-Brx)*2/1000 !励磁线圈间隙
Hrx=83/1000 !励磁线圈高
Ar=Hrx*Brx !励磁线圈面积
Nr=270 !励磁线圈匝数
Ir=22 !励磁线圈电流
U_Hrx=2/1000 !励磁线圈距离转子铁心上部长度
D_Hrx=3.5/1000 !励磁线圈距离转子铁心下部长度
Hrz=56/1000 !转子支撑轭高
Hrz1=15/1000 !转子支撑轭高1
Hrs=15/1000 !定子槽深
Brz=28.5/1000 !转子支持轭宽
Rr=8/1000 !转子螺孔半径
Rrr=7/1000 !转子铁心螺丝半径
Hrf=42/1000 !螺孔中心高
Brf=33.25/1000 !螺孔中心宽
Hrj=88.5/1000 !转子轭高
Bst=43/1000 !定子齿宽
Bss=43/1000 !定子槽宽
Hss=41/1000 !定子槽深
Hsj=89.5/1000 !定子轭高
Ds=38.7/1000 !定子绕组直径(带绝缘)
Rs=Ds/2 !定子绕组半径(带绝缘)
!Rss=10.2/1000 !定子绕组半径(纯铝线)
Rss=10.2/1000
As=3.1416*Rs*Rs !定子线圈截面积
!端部参数
Ri=70/1000 !导线内转弯半径
Ro=108.7/1000 !导线外转弯半径
Rm=(Ri+Ro)/2 !平均转弯半径（建模时用到）
Ls=170/1000 !铁心长度
Lwv=242.6/1000 !导线直线部分长度（横向）
Lwh=79.3/1000 !导线直线部分长度（纵向：运动方向）
/prep7
et,1,97
mp,murx,1,1 !air
mp,murx,2,1 !coil
mp,murx,3,1 !coil
mp,murx,4,1 !coil
mp,murx,5,1 !coil
mp,murx,6,1 !coil
mp,murx,7,1 !coil
mp,murx,8,1 !coil
mp,murx,9,1 !coil
mp,murx,10,1 !coil
mp,murx,11,3000 !iron
/pnum,volu,1
local,20,0,0,0,Lwv/2
wpcsys,,20
!画六个槽
block,-Bst/2,Bst/2,-Hss/2,Hss/2,-Ls/2,Ls/2
block,1.5*Bst,2.5*Bst,-Hss/2,Hss/2,-Ls/2,Ls/2
block,3.5*Bst,4.5*Bst,-Hss/2,Hss/2,-Ls/2,Ls/2
block,5.5*Bst,6.5*Bst,-Hss/2,Hss/2,-Ls/2,Ls/2
block,7.5*Bst,8.5*Bst,-Hss/2,Hss/2,-Ls/2,Ls/2
block,-2.5*Bst,-1.5*Bst,-Hss/2,Hss/2,-Ls/2,Ls/2
!画定子铁心
block,-3*Bst,9*Bst,-Hss/2,Hsj-Hss/2,-Ls/2,Ls/2
vovlap,all
numcmp,volu
vplot
vdele,1,6,1
numcmp,volu
vplot
local,11,0,-Rm,0,Rm+Lwv
wpcsys,,11
wprota,,,270
cylind,0,Rs,0,Lwh/2,0,360
local,12,1,-Rm,0,Lwv,0,270
wpcsys,,12
!wprota,,270 :如果旋转不是直接加到local中，给弯道加电流时会很麻烦。
torus,0,Rs,Rm,270,360
local,13,0,0,0,0
wpcsys,,13
cylind,0,Rs,0,Lwv,0,360
local,14,1,Rm,0,0,0,270
wpcsys,,14
torus,0,Rs,Rm,90,180
local,15,0,Rm,0,-Rm
wpcsys,,15
wprota,,,270
cylind,0,Rs,0,-Lwh,0,360
local,16,1,Rm+Lwh,0,0,0,270
wpcsys,,16
torus,0,Rs,Rm,0,90
local,17,0,2*Rm+Lwh,0,0
wpcsys,,17
cylind,0,Rs,0,Lwv,0,360
local,18,1,3*Rm+Lwh,0,Lwv,0,270
wpcsys,,18
torus,0,Rs,Rm,270,180
local,19,0,3*Rm+Lwh,0,Rm+Lwv
wpcsys,,19
wprota,,,270
cylind,0,Rs,0,-Lwh/2,0,360
vsel,s,volu,,2,10
vglue,all
numcmp,volu
vplot
allsel,all
local,21,0,0,0,Lwv/2
wpcsys,,21
block,-3*Bst,9*Bst,-Hss/2-3*Hsj,2*Hsj-Hss/2,-lwv,lwv
vovlap,all
numcmp,volu
vplot
allsel,all
!剖分
vsel,s,volu,,1
vatt,11,,1,0
vsel,s,volu,,2
vatt,2,,1,0
vsel,s,volu,,3
vatt,3,,1,12
vsel,s,volu,,4
vatt,4,,1,0
!local,23,1
vsel,s,volu,,5
vatt,5,,1,14
vsel,s,volu,,6
vatt,6,,1,0
vsel,s,volu,,7
vatt,7,,1,16
vsel,s,volu,,8
vatt,8,,1,0
vsel,s,volu,,9
vatt,9,,1,18
vsel,s,volu,,10
vatt,10,,1,0
vsel,s,volu,,11
vatt,1,,1,0
allsel,all
smrt,8
mshkey,0
mshape,1,3d
vmesh,all
!apply loads to the model
*dim,cur,array,1
*dim,coils,char,1
cur(1)=Is
coils(1)='wind1'
js1=cur(1)*Ns/As
/solu
esel,s,mat,,2
esel,a,mat,,6
esel,a,mat,,10
bfe,all,js,,js1 !current density in the 'x' direction
esel,s,mat,,4
bfe,all,js,,,,-js1
esel,s,mat,,8
bfe,all,js,,,,js1 !current density in the 'z' direction
esel,s,mat,,3
esys,12
bfe,all,js,1,,js1
esel,s,mat,,5
esys,14
bfe,all,js,1,,-js1
esel,s,mat,,7
esys,16
bfe,all,js,1,,-js1
esel,s,mat,,9
esys,18
bfe,all,js,1,,js1 !current density in the 'theta' direction
allsel,all
nsel,s,loc,y,2*Hsj-Hss/2
nsel,s,loc,y,-Hss/2-3*Hsj
nsel,a,loc,z,-lwv
nsel,a,loc,z,lwv
d,all,az,0
allsel,all
esel,s,mat,,2,10
cm,coils(1),elem
allsel,all
FINI
/COM
/COM OBTAIN OPERATING SOLUTION
/COM
!
/SOLU
CNVTOL,CSG,,1.0E-4
!eqslv,JCG
SOLVE
FINI
/post1
lmatrix,1,'wind','cur','ind' </PRE>
谢谢
谢谢你，支持，希望继续发些关于直线电机的模型！
页:
[1]