求助！ansys计算转子动力学
我想哪位高手可以帮我计算一个圆柱筒结构考虑陀螺效应，在一定转速下的坎贝尔图，不胜感谢！！！ 本帖最后由 Rainyboy 于 2010-10-17 12:50 编辑直接求代码不合适吧，建模和边界条件与一般的场合没有区别，LZ自己可以搞定。
求解的APDL命令流大概是这样的(这是我曾经用到的，你实际用的时候也许需要做一些改动)：
!Solve
/solu
antype,modal
modopt,qrdamp,5,,,on !QRDAMP复模态分析方法
coriolis,on,,,on !考虑柯氏力，并在固定坐标系中求解（只有这样，才能将结果用于汇出坎贝尔图）
!计算5个转速下的模态
*DO,I,0,5,1
omega,,,I*200 !这里的单位是rad/s，而且应当注意在旋转的中心轴是哪个轴
mxpand,5
solve
*ENDDO
finish
/POST1
!画坎贝尔图，并汇出一条斜率是1的直线，设置横坐标的单位是RPM
plcamp,on,1,RPM
finish
回复 Rainyboy 的帖子
非常感谢您的回复，我先试着计算一下，不胜感激！多多学习！ 回复 leishengmei 的帖子
问题解决之后有什么心得欢迎回来分享哈！ 看来还不顺利，我计算的结果怎么和不考虑陀螺效应一样呢，正确的结果应该是随着转速的升高频率增加的，和我的模型有关吗？我的模型是空心圆柱体 回复 Rainyboy 的帖子
我用简单的圆柱筒模型进行计算，结果也是一样的，是否ANSYS只对转子模型计算考虑陀螺效应还是我的模型有问题吗？您能帮我计算个简单圆筒模型，两端是封闭的盖？ 回复 leishengmei 的帖子
如果可以的话，你把你使用的APDL发上来吧，大家也都好给你看看，呵呵 回复 Rainyboy 的帖子
我的模型文件
fini
/clear
/prep7
ET,1,mesh200
keyopt,1,1,6
ET,2,solid45
MP,EX,1,71E9
MP,PRXY,1,0.33
MP,DENS,1,2800
K,1,,,,
K,2,0.049,,,
K,3,0.048,0.002,,
K,4,0.048,0.098,,
K,5,0.049,0.1,,
K,6,0,0.1,,
K,7,0,0.098,,
K,8,0,0.002,,
A,8,3,4,7,6,5,2,1
AATT,1,,1,0
ESIZE,0.004,0
AMESH,ALL
TYPE,2
EXTOPT,ATTR,1,1,0
EXTOPT,ESIZE,18,0
EXTOPT,ACLEAR,1
VROTAT,ALL,,,,,,1,8,360,2
/SOL
ANTYPE,2
MODOPT,LANB,10
EQSLV,SPAR
MXPAND,10,,,1
LUMPM,0
PSTRES,0
MODOPT,LANB,10,0,10000,,OFF
SOLVE
这是我的模型，不考虑陀螺效应的结果和采用您给我的考虑陀螺效应的结果一样，两者应该是不一样的。 回复 Rainyboy 的帖子
您有空的话，帮我看看，问题出在哪？非常感谢！ 回复 leishengmei 的帖子
跑了下，看得出分网挺费心思的。代码貌似有两个问题：
1，没有位移约束，我在你的建模代码里添加了：
NSEL,S,LOC,Y,0
D,ALL,ALL,0得到坎贝尔图为：
其中，涉及弯曲的模态都随着转速的变化，产生了固有频率的变化，应该是符合预期的（第一阶扭转没有受影响，也是预期之中的）。
2，分网有问题，产生的警告，有些模态位移很乱，对圆盘的分网建议分成这样：
就是这些了，楼主参考参考？
回复 Rainyboy 的帖子
能否把你计算的命令流发到我的邮箱里，我的邮箱是leishengmei2002@163.com,我学习一下 回复 leishengmei 的帖子
不好意思，这两天赶一个项目，既没有回复你也没有给你发邮件。
代码我贴在这里吧，供你参考（咱们论坛不建议大家留下邮箱私自解决了事哈，呵呵）：
FINISH
/CLEAR
/TITLE,A MODE ANALYSIS FOR SINGLE DISC ROTATE SYS
!Parameters
*SET,L1,305 !轴段1的长度
*SET,L2,500 !轴段2的长度
*SET,R_AXIS,30 !实心轴的直径
*SET,R_DISC,300 !实心盘的直径
*SET,H_DISC,25 !实心盘的厚度
*SET,MEX,2.06E5 !材料弹性模量
*SET,MNUXY,0.3 !材料泊松比
*SET,MDENS,7.8E-9 !材料密度
*SET,NMESH_CIR,5 !
*SET,NMESH_R,8 !
*SET,NMESH_HDISC,3!
!CONST
*SET,PI,4*ATAN(1)
!Model
!Path Lines
/PREP7
K,100,0,0,0
K,101,0,0,-1*H_DISC
K,102,0,0,L2
K,103,0,0,L1+L2
L,100,101
L,100,102
L,102,103
!LINES
CIRCLE,100,R_AXIS/2
CIRCLE,100,R_DISC/2
L,3,7
L,1,5
L,2,6
L,4,8
!AREAS
AL,4,5,6,7
AL,9,12,14,5
AL,4,14,8,13
AL,7,13,11,15
AL,12,6,15,10
!VOLUMES
VDRAG,1,,,,,,1
VDRAG,1,,,,,,2
ASEL,S,LOC,Z,L2
VDRAG,ALL,,,,,,3
ALLSEL,ALL
VDRAG,2,,,,,,1
VDRAG,3,,,,,,1
VDRAG,4,,,,,,1
VDRAG,5,,,,,,1
!MESHSETTINGS
CSYS,1
LSEL,S,LOC,Z,L2
LSEL,A,LOC,Z,L1+L2
LESIZE,ALL,,,NMESH_CIR
ALLSEL,ALL
LSEL,S,LOC,Z,0
LSEL,A,LOC,Z,-1*H_DISC
LSEL,R,LOC,X,R_DISC/2
LESIZE,ALL,,,NMESH_CIR
ALLSEL,ALL
LSEL,S,LOC,Z,0
LSEL,A,LOC,Z,-1*H_DISC
LSEL,R,LOC,X,R_AXIS/2
LESIZE,ALL,,,NMESH_CIR
ALLSEL,ALL
LSEL,S,LOC,Z,0
LSEL,A,LOC,Z,-1*H_DISC
LSEL,U,LOC,X,R_AXIS/2
LSEL,U,LOC,X,R_DISC/2
LESIZE,ALL,,,NMESH_R
ALLSEL,ALL
LSEL,S,LOC,X,R_AXIS/2
LSEL,U,LOC,Z,0,-1*H_DISC
LSEL,U,LOC,Z,L2
LSEL,U,LOC,Z,L1+L2
LESIZE,ALL,20
ALLSEL,ALL
LSEL,S,LOC,X,R_DISC/2
LSEL,A,LOC,Z,0,-1*H_DISC
LSEL,U,LOC,Z,0
LSEL,U,LOC,Z,-1*H_DISC
LESIZE,ALL,,,NMESH_HDISC
ALLSEL,ALL
ET,1,SOLID45
MP,EX,1,MEX
MP,NUXY,1,MNUXY
MP,DENS,1,MDENS
MSHAPE,0,3D
VMESH,ALL
ALLSEL,ALL
!DOF constraints
CSYS,1
NROTAT,ALL
ALLSEL,ALL
LSEL,S,LOC,X,R_AXIS/2
LSEL,R,LOC,Z,L2
NSLL,S,1
D,ALL,UX,0
D,ALL,UY,0
ALLSEL,ALL
!NSEL,S,LOC,Z,L1+L2
LSEL,S,LOC,X,R_AXIS/2
LSEL,R,LOC,Z,L1+L2
NSLL,S,1
D,ALL,ALL
ALLSEL,ALL
CSYS,0
NUMMRG,ALL
!Solve
/solu
antype,modal
modopt,qrdamp,5,,,on
! stationary reference frame
coriolis,on,,,on
!
*DO,I,0,5,1
omega,,,I*200
mxpand,5
solve
*ENDDO
finish
/POST1
! Plot Campbell Diagram
plcamp,on,1,RPM
finish
模型画出来是这样的：
画出来的坎贝尔图是这样的：
这个模型我是我学习的时候练习用的，我和另外一个同学分别作出了相同的结果（他UGI，我APDL），应该没什么大错吧。
回复 12 # Rainyboy 的帖子
您好，我正在做转子动力学课题，参考了很多论文用ansys好像可以计算临界转速，但我对ansys没有用过，最近想用它分析转子临界转速，可是不知从何学起，很是苦恼，高手能否指点一下，非常感谢！ 回复 13 # kateding 的帖子
不是什么高手哈，大家共同学习。
说道参考资料，ANSYS的帮助文档用来熟悉和上手足够了。
详见ANSYS HELP 的Advanced GUide 中的第八章 Rotating Structure Analysis，有各种命令的详细解释，还有例子，而且阅读过程中还可以学学英语，挺好的，呵呵 回复 14 # Rainyboy 的帖子
刚接触ansys，查阅了一些书籍，ansys好像都没有关于转子动力学方面的？请问哪个版本里有啊？