关于加强筋平板模态分析与导出
有站友发信请教ansys与sysnoise的联合计算问题,希望下面这个例子对于你们有所帮助.由于sysnoise不能分析加肋板的振动模态,因此无法分析加肋板的辐射与散射问题.可以采用ansys或者patran计算加肋板的模态,再导入sysnoise计算声场.以下便是ansys命令流,可以得到加肋板网格文件以及模态文件(fre格式). 在sysnoise中建立有限元模型导入网格文件(肋自动删除)与模态文件,设置激励力,再建立间接边界元模型,二者耦合计算辐射声场.
1.ansys中建了一个自由的加强筋（beam 189）平板（shell 93），计算模态
2.导出ansys网格，命令：cdwrtie,all,myfilename,cdb；修改版本号为5.7
3.select与板关联的节点，确定平板上所有节点标号，例如本例中节点编号范围为1619-11641；
4.修改本版导出模态命令流" *Do,ii,1, nodenumber,1"为" *Do,ii,1619, 11641,1 "，在ansys中读入命令流文本（直接粘贴到命令行中不行） ；
5.将网格导入sysniose。尽管sysnoise仅识别板单元、不识别加强筋单元，但是可以正常给出光板模型；
6.导入free格式模态，察看倒入模态结果。
7.余下处理方法和平板一样，不再赘述。
若模态振型函数有接近的情况，sysnoise可能会自动合并，因此出现共振频率与振型分布“窜位”的现象。对于非自由约束条件而言，模态振型函数相接的概率可以降低；或者不导出模态振型函数接近的模态（通常为前几阶）。
FINISH
/CLEAR
/FILNAM, SHELL-BEAM
/TITLE, THE SHELL AND BEAM MODEL
/PNUM, KP, 1
!* 打开关键点数字显示
/PNUM, LINE, 1
/PNUM, AREA, 0
/NUMBER, 0
!* 设置显示实体编号时，编号与颜色是否一起显示
/VIEW, 1, 0.64, -0.67, 0.37
/ANG, 1, -70
/PREP7
ET, 1, SHELL93
ET, 2, BEAM189
R, 1, 0.04
!* 1号截面：方形截面
SECTYPE, 1, BEAM, HREC, Box-sect, 0
SECOFFEST, CENT
SECDATA, 0.1, 0.1, 0.01, 0.01, 0.01, 0.01, 0,0,0,0
!*2号截面：L形截面
SECTYPE, 2, BEAM, L, L-sect, 0
SECOFFSECT, CENT
SECDATA, 0.12, 0.1, 0.01, 0.01, 0, 0, 0, 0, 0, 0
!*定义材料1：板
MP, EX, 1, 2E11
MP, PRXY, 1, 0.3
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,DENS,1,,7800
!*定义材料2：加强肋
MP, EX, 2, 2E11
MP, PRXY, 2, 0.3
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,DENS,2,,7800
!*定义12个关键点
K, 1, 0, 0
K, 2, 0, 1
K, 3, 0, 2
K, 4, 0, 3
K, 5, 12, 0
K, 6, 12, 1
K, 7, 12, 2
K, 8, 12, 3
K, 9, 0, 0, 1
K, 10, 0, 1, 1
K, 11, 0, 2, 1
K, 12, 12, 3, 1
!* 定义3个面
A, 1, 5, 6, 2
A, 2, 6, 7, 3
A, 3, 7, 8, 4
GPLOT
!* 分配四边框线的单元属性
LSEL, S, LOC, X, 0
LSEL, A, LOC, Y, 0
LATT, 2, 1, 2, , 9, , 1
LSEL, S, LOC, X, 12
LSEL, A, LOC, Y, 3
LATT, 2, 1, 2, , 12, , 1
!* 分配X向中间2条线的单元属性
LSEL, S, LOC, Y, 1
LATT, 2, 1, 2, , 10, , 2
LSEL, S, LOC, Y, 2
LATT, 2, 1, 2, , 11, ,2
!* 控制线上的单元尺寸
LSEL, ALL
LESIZE, ALL, 0.1, , , , , , , 1
!* 划分线上梁单元网格
LMESH, ALL
/ESHAPE, 1.0
EPLOT
!* 分配面上的单元属性
AATT, 1, 1, 1, 0, 1
!* 划分面上的单元网格
AESIZE, ALL, 0.1,
!* 划分面上的单元网格
MSHAPE, 0, 2D
MSHKEY, 1
AMESH, ALL
!*修改Box-sect梁单元网格
SECTYPE, 1, BEAM, HREC, Box-sect, 0
SECOFFSET, USER, 0, 0.1+0.01/2
SECDATA, 0.1, 0.1, 0.01, 0.01, 0.01, 0.01, 0, 0, 0, 0
!*修改L-sect梁单元网格
LREVERSE, 3, 0
SECTYPE, 2, BEAM, L, L-sect, 0
SECOFFSET, USER, 0, 0.1-0.01/2+0.01/2
SECDATA, 0.12, 0.1, 0.01, 0.01, 0, 0, 0, 0, 0, 0
SAVE
FINISH
/SOLU
!*
ANTYPE,2
!*
MSAVE,0
!*
*set,modenum,50
!指定模态的阶数
MODOPT,LANB,modenum
EQSLV,SPAR
MXPAND,modenum, , ,0
LUMPM,1
PSTRES,0
!*
MODOPT,LANB,modenum,0,4000, ,OFF
! /STATUS,SOLU
SOLVE
! SAVE, SHELL-BEAM,db,
!从ANSYS中导出模态频率及振型数据
/Post1
*Cfopen,modefile_ansys,fre
!打开文件
*Vwrite
('SYSNOISE MODES STRUCTURE FILE')
!头文件
*Vwrite
('Rev 5.5
Windows NT
30NOV2000')
*Vwrite
('SYSNOISE Default Model')
*Vwrite
('23-JUN-2008 10:22:59')
*Do,i,1,modenum,1
*Vwrite
('REAL MODE
FREQUENCY
EIGENVALUE')
*Get,modefq,mode,i,freq
bb='%i%'
modeanglefq = modefq*modefq*2*2*3.141593*3.141593
*Vwrite, bb, modefq, modeanglefq
(A10,2e20.8)
*Vwrite
('DISPLACEMENT VALUES')
set,1,i
*Do,ii,
1619, 11641,1
!对于复杂情况，表面节点编号不一定是从1开始且连续的
*Get,modeshpx,node,ii,u,x
*Get,modeshpy,node,ii,u,y
*Get,modeshpz,node,ii,u,z
modeshprx = 0
!SOLID45单元没有旋转分量
modeshpry = 0
modeshprz = 0
bb1 ='%ii%'
bb2 ='
'
*vwrite,bb1,bb1,modeshpx,modeshpy,modeshpz
(2A10,3e20.8)
*vwrite,bb2,modeshprx,modeshpry,modeshprz
(A20,3e20.8)
*Enddo
*Enddo
*cfclos
FINISH
[ 本帖最后由 w89986581 于 2009-3-24 20:13 编辑 ] sysnoise是因为本身技术的缺陷而不能分析加筋板的声辐射呢，还是因为加筋对板的声辐射影响不大？
回复 沙发 oyzy83scut 的帖子
前者,肋与流体耦合相对于板与流体耦合小得多,但是肋增加了板的刚度,对辐射声场的影响还是不容忽视的. 原帖由 w89986581 于 2009-3-24 23:06 发表 http://www.chinavib.com/forum/images/common/back.gif前者,肋与流体耦合相对于板与流体耦合小得多,但是肋增加了板的刚度,对辐射声场的影响还是不容忽视的.
如果筋对声场辐射的影响不容忽视，请问通过导入模态的方式能有多大的精度去再现加强筋板的声辐射问题？或者有没有哪个震动声分析软件可以分析带筋板的？
页:
[1]