【转贴】[命令和APDL] 实数及数组的输出与示例
本帖最后由 coohit 于 2016-8-10 11:11 编辑转帖
实数及数组的输出与示例
一、实数的输出
①实数的输出比较简单，类似FORTRAN的可采用D/E//F/G格式输出。例如：
*CFOPEN,MYFILE,TXT
X1=4.56
X2=12345.678
X3=1.23E-6
*VWRITE,X1,X2,X3
(3d15.6)
*VWRITE,X1,X2,X3
(3E15.6)
*VWRITE,X1,X2,X3
(3f15.6)
*VWRITE,X1,X2,X3
(3g15.6)
*CFCLOSE
文件MYFILE.TXT如下：
0.456000D+01
0.123457D+05
0.123000D-05
0.456000E+01
0.123457E+05
0.123000E-05
4.560000
12345.678000
0.000001
4.56000
12345.7
0.123000E-05
②当采用科学计数时，输出格式的第一位都是“0”开头，如上文中的0.123457E+05，假如我们希望写成1.234568E+04或12.345678E+03的格式时，可采用如下格式：1PE15.6或2PE15.6。则上文中的命令流可改为：
*VWRITE,x1,x2,x3
(3(1pe15.6))
或
*VWRITE,x1,x2,x3
(1pe15.3,3pe15.4,1pe15.6)
③采用C格式输出实数
C格式也有d-整型、f-浮点、e-科学、g-任意、c-字符、s-字符串等格式，均采用%w.dx形式，而%/则为回车换行。例如：
*CFOPEN,MYFILE,TXT
X1=4.56
X2=12345.678
X3=1.23E-6
*VWRITE,X1,X2,X3,4567
%14.6f%15.6e%16.6g%10d
*CFCLOSE
文件MYFILE.TXT如下：
4.560000
1.234568E+04
1.230000E-06
4567
二、数组的输出
(一)VWRITE方法
数组输出格式同上，但其输出控制却有很多种形式，且ANSYS按列输出数组。
设有数组(矩阵形式，这里不用插图了)：
|1.12.13.1|
|1.22.23.2|
ABC(5,3)=|1.32.33.3|
|1.42.43.4|
|1.52.53.5|
*VWRITE命令如下几种方式：
① 与矩阵写法类同的按列输出：利用ANSYS的输出特点，分别写出各列表示符即可，而行则从1到最终的5。
② 同上格式，但按矩阵元素输出用一对()将矩阵表达式括起来变为矩阵元素，这样用循环输出，如命令流中所示。
③当列很多时不可能写出每个列字符表达式，此时可采用$字符格式$字符表示连续输出，没有回车符号，当一行写完后，增加一个非$格式语句即可。但是这里增加了一个临时数组，以存储某行的数据。
上述输出格式便于导入EXCELL中处理数据。
(二)MWRITE命令
数组最好采用*MWRITE命令输出，不管是否按类似矩阵格式输出，此命令均可较好解决。当矩阵列数较少时，可以采用类似行列输出；当矩阵列数很大时，可以按每行N个数据控制输出。
以上4种方法的命令流如下：
*DIM,ABC,,5,3
!数组赋值
*DO,I,1,5
*DO,J,1,3
ABC(I,J)=J+I/10
*ENDDO
*ENDDO
!VWRITE数组输出
*CFOPEN,MYFILE,TXT
!①格式1-按行列输出(行数从1~最终的5，列不变)
*VWRITE,ABC(1,1),ABC(1,2),ABC(1,3)
(3F6.1)
!②格式2-按矩阵元素输出
*DO,I,1,5
*VWRITE,(ABC(I,1)),(ABC(I,2)),(ABC(I,3))
(3F6.2)
*ENDDO
!③格式3-多列时按行列输出
*DIM,TELS,,3
*DO,I,1,5
*DO,J,1,3
TELS(J)=ABC(I,J)
*ENDDO
*VWRITE,TELS(1)
(F6.3,$)
*VWRITE
('
')
*ENDDO
*CFCLOSE
!④MWRITE输出数组
!ABCD(I,J,K)
*DIM,ABCD,,50,30
!数组赋值
*DO,I,1,50
*DO,J,1,30
ABCD(I,J)=j+i/100
*ENDDO
*ENDDO
*MWRITE,ABCD,MYFILE1,TXT,,JIK,30,50
(30F9.4)
!也可采用(10f9.4)格式，以输出150行*10个的数据。
文件MYFILE.TXT可以通过记事本查看。
1.1 2.1 3.1
1.2 2.2 3.2
1.3 2.3 3.3
1.4 2.4 3.4
1.5 2.5 3.5
1.102.103.10
1.202.203.20
1.302.303.30
1.402.403.40
1.502.503.50
1.100 2.100 3.100
1.200 2.200 3.200
1.300 2.300 3.300
1.400 2.400 3.400
1.500 2.500 3.500
文件MYFILE1.TXT的内容可通过EXCELL打开：EXCELL>打开(所有文件)>选择MYFILE1.TXT>选择分隔符>下一步>选择空格>完成，该表为50行*30列的数据表。
页:
[1]