zongdao 发表于 2008-4-25 17:22

两圆柱体的接触，请指教

初学接触分析，有问题不明，幸勿见笑。
我的问题是这样的，求解两个圆柱体之间的接触应力（只画出四分之一的模型）。我以上面的圆柱面为接触面，
下面的圆柱面为目标面。在面1上作用均布压力，并耦合此面上的节点的Y向（垂直于1面）自由度。在对称面上施加对称约束，约束下圆柱体的位移。
为什么计算时还显示上面的圆柱体的Y向位移超过10000呢？我觉得已经上述的约束已经足够了，可为什么还是显示位移约束不够么？。请各位高才不吝赐教。

还有一个问题，为什么我设置接触对时，只能选择柔柔接触，而不能选择刚柔接触呢

[ 本帖最后由 zongdao 于 2008-4-25 17:30 编辑 ]

16443 发表于 2008-4-25 19:09

你好像没有约束下边圆柱的Y向位移啊。
检查一下边界条件、

rodge 发表于 2008-4-25 22:34

这样的接触，很容易出现这样的情况，设置接触行为keypot(12)为绑定状态就可以

zongdao 发表于 2008-4-26 21:08

回复 3楼 的帖子

谢谢两位:handshake 。我试一下

paradiseboy 发表于 2008-5-5 14:26

你选择的什么接触单元？
我刚按照书上做过一个类似的例子（ANSYS机械工程应用25例，电子工业出版社——第13例 平行圆柱体承受法向载荷时的接触应力分析），书上选用的contac49，用于节点对面的接触。

我换成面面接触，在分析时提示有刚性位移。然后加了一定的初始渗透，可以分析出结果。
书上提供的命令流如下，可以参考：
/CLEAR

/PREP7
ET,1,PLANE42
ET,2,SOLID45
ET,3,CONTAC49
MP,EX,1,2E11
MP,PRXY,1,0.3
CYL4,0,0,0.1,0,0,90
CYL4,0,0.15,0.05,-90,0,0
WPOFF,0.01
WPROT,0,0,90
ASBW,ALL
AATT,1,1,1
ESIZE,0.0075
MSHAPE,0
MSHKEY,1
AMESH,ALL
KREFINE,2,4,2,2
TYPE,2
EXTOPT,ESIZE,10
EXTOPT,ACLEAR,1
VEXT,ALL,,,,,0.1
FINISH

/SOLU
DA,16,UY
DA,8,UY
DA,15,UX
DA,20,UX
DA,1,UZ
DA,9,UZ
DA,13,UZ
DA,17,UZ
ASEL,S,,,11,19,8
NSLA,S,1
SFA,ALL,1,PRES,2E5
CP,1,UY,ALL
ALLSEL,ALL
FINISH

/PREP7
R,1,2E10
ASEL,S,,,14
NSLA,S,1
CM,SNAPINS,NODE
ASEL,S,,,18
NSLA,S,1
CM,SNAPPRG,NODE
ASEL,ALL
NSEL,ALL
TYPE,3
REAL,1
GCGEN,SNAPINS,SNAPPRG
GCGEN,SNAPPRG,SNAPINS
FINISH

/SOLU
PRED,ON
AUTOTS,ON
!NLGEOM,ON
NSUBST,6,100,4
OUTRES,ALL,ALL
SOLVE
FINISH

/POST1
SET,LAST
ESEL,S,TYPE,,3
ETABLE,FN,SMISC,1
ETABLE,ST,NMISC,1
ETABLE,GAP,NMISC,3
ESORT,ETAB,FN,1
PRETAB,FN,ST,GAP
FINISH

jxxansys 发表于 2009-5-28 12:22

/CLEAR
/FILNAME, EXAMPLE16

/PREP7
ET,1,PLANE183
ET,2,SOLID186
ET,3,TARGE170

ET,4,CONTA174,,,,,1

R,1,,,0.1

MP,EX,1,2E11
MP,PRXY,1,0.3
CYL4,0,0,0.1,0,0,90
CYL4,0,0.15,0.05,-90,0,0
WPOFF,0.01
WPROT,0,0,90
ASBW,ALL
AATT, 1, 1, 1
ESIZE,0.0075
MSHAPE,0
MSHKEY,0
AMESH,ALL
KREFINE,2,4,2,3
TYPE,2

EXTOPT,ESIZE,5

EXTOPT,ACLEAR,1
VEXT,ALL,,,,,0.01
ASEL,S,,,14
NSLA,S,1
REAL,1
TYPE,3
ESURF
ALLS
ASEL,S,,,18
NSLA,S,1
REAL,1
TYPE,4
ESURF
ALLS
FINISH


/SOLU
DA,16,UY
DA,8,UY
DA,15,UX
DA,20,UX
DA,1,UZ
DA,9,UZ
DA,13,UZ
DA,17,UZ
ASEL,S,,,11,19,8
NSLA,S,1
SFA,ALL,1,PRES,1E6
CP,1,UY,ALL
ALLS
LNSRCH,ON
AUTOTS,ON
NSUBST,5,10,3
OUTRES,ALL,ALL
SOLVE
FINISH

/POST1
ESEL,S,TYPE,,4
ETABLE,PRES,CONT,PRES
ETABLE,ST,CONT,STAT
ETABLE,GAP,CONT,GAP
ESORT,ETAB,PRES,0
PRETAB,PRES,ST,GAP,PENE
FINISH

无水1324 发表于 2009-5-29 17:38

回复 6楼 jxxansys 的帖子

给点说明或者解释？这样我才知道你这个命令流是做什么的？

jxxansys 发表于 2009-5-30 21:58

回复 7楼 无水1324 的帖子

两圆柱体的接触

jxxansys 发表于 2009-6-2 13:56

回复 7楼 无水1324 的帖子

ANSYS机械工程应用25例，电子工业出版社——第13例 平行圆柱体承受法向载荷时的接触应力分析
使用11。0版本后新的命令流

dgdsafd 发表于 2012-11-29 16:20

jxxansys 发表于 2009-5-28 12:22 static/image/common/back.gif
/CLEAR
/FILNAME, EXAMPLE16



您好，ansys中两圆柱的接触问题一直做不成功，希望老师您能将书上的步骤拍几张图片上来看看，谢谢您了！
页: [1]
查看完整版本: 两圆柱体的接触，请指教