用shell131做的复合材料热分析算例（转贴）
本算例为4层石墨环氧反对称角铺层方板，边长0.08m，厚度0.008m，加载热流于上表面中心区，面积 0.0004m*m，大小为100000W/m*m,材料主轴热导率K11=30W/mK,k22=k33=1.1，对流换热系数a=30W/m*mK.finish
/clear
/prep7
et,1,shell131,,,1,8!热分析用4节点分层壳单元
sectype,1,shell
mp,kxx,1,30 !45度方向材料属性
mp,kyy,1,1.1
mp,kzz,1,1.1
mp,c,1,1000
mp,dens,1,1389.2
mp,kxx,2,30 !－45度方向材料属性
mp,kyy,2,1.1
mp,kzz,2,1.1
mp,c,2,1000
mp,dens,2,1389.2
secdata,0.001,1,45 !进行各个铺层厚度、材料、方向设定
secdata,0.001,2,-45
secdata,0.001,1,45
secdata,0.001,2,-45
secdata,0.001,1,45
secdata,0.001,2,-45
secdata,0.001,1,45
secdata,0.001,2,-45
n,1, !建模
n,17,0.08
fill,1,17
ngen,17,17,1,17,1,,0.005
e,1,2,19,18
egen,16,1,1
egen,16,17,1,16
esel,s,,,136,137
esel,a,,,120,121
sfe,all,2,hflux,,1e5!在顶面加载热流载荷
esel,all
finish
!!!!!!!!!!!!!!!!!static
/solu!稳态
antype,static
tref,20
sfe,all,1,conv,1,30
sfe,all,1,conv,2,20
esel,u,,,136,137
esel,u,,,120,121 !对未加载单元顶面、所有单元底面
sfe,all,2,conv,1,30 !定义边界的空气对流换热
sfe,all,2,conv,2,20
esel,all
outres,all,all
solve
/post1
plnsol,tbot !分层显示各个层底温度分布
plnsol,te2 !由底面到顶面
plnsol,te3
plnsol,te4
plnsol,te5
plnsol,te6
plnsol,te7
plnsol,te8
plnsol,ttop
path,ppp,9 !定义沿X方向半对称轴路径
ppath,1,145
ppath,2,146
ppath,3,147
ppath,4,148
ppath,5,149
ppath,6,150
ppath,7,151
ppath,8,152
ppath,9,153
pdef,pop,ttop !显示本路径顶面温度变化
plpath,pop
转自simwe {:{23}:}好东西
页:
[1]