请教：能否用ansys ls-dyna模拟岩石（落石）冲击土体过程？
各位老大，请教：能否用ansys ls-dyna模拟岩石（落石）冲击土体过程？能否得到冲击力、土体应力、变形等参数？模拟过程中需要注意哪些问题？
谢谢~~ 我也很想知道啊{:{13}:} 应该可以，这个问题和动力学侵彻问题一样，给石头块施加一个初速度，定义好石头和土坯的材料参数最重要。LS-DYNA的后处理器中可以直观的看出应力，压力云图以及土坯的破坏情况，如果你要看的比较细，建议你使用配置较好的电脑，选择小一点的动画步长。 ANSYS/LS-DYNA模拟落石冲击地面的案例
/title,Test No.A028
/PREP7
et,1,solid164 !ANSYS/LS-DYNA采用显式求解，ANSYS采用的是隐式求解
et,2,solid164
et,3,shell163
H=2.95 !落石高度
Lside=0.30 !落石边长
LX=5.0*Lside !模型X轴边界范围
LY=5.0*Lside !模型Y轴边界范围
LZ=5.0*Lside !模型Z轴边界范围
EL=20
vector=sqrt(2*9.8*H) !m/s
TT=0.006
DTT=1000 !SQRT(2*h/9.8)+3.0
DENS2=2390 !落石的密度*9.8
FORC1=DENS2*Lside**3*9.8 !落石的自重
!地面岩土体--碎石土
MP,EX,1,1.0e9
MP,NUXY,1,0.24
MP,DENS,1,2100
TB,BISO
TBDATA,1,1.2e6,4.0e5 !屈服应力,越大回弹越高;切线模量,越大回弹越高
!落石
MP,EX,2,5.0e10
MP,NUXY,2,0.24
MP,DENS,2,DENS2
k,1,0.0,LY,-LZ
k,2,0.0,0,-LZ
k,3,2*LX,LY,-LZ
k,4,2*LX,0,-LZ
K,5,0.0,0.0,LZ
A,1,2,4,3
LESIZE,all,Lside/2,,,, , , ,1
amesh,all
l,2,5
TYPE,1
EXTOPT,ESIZE,EL,1,
EXTOPT,ACLEAR,1
EXTOPT,ATTR,0,0,0
MAT,1
REAL,1
ESYS,0
VDRAG,1,,,,,,5
cm,nsoil,node
cm,esoil,elem
ldele,5,,,1
allsel,all
!建立落石几何模型
block,LX-Lside/2,LX+Lside/2,LY,LY+Lside,-Lside/2,Lside/2
vsel,,,,2
vatt,2,2,2
aslv,s
lsla,s
LESIZE,ALL,,,2,1
vmesh,2
eslv,s
nsle,s
cm,nrock,node
cm,erock,elem
EDMP,RIGID,2,6,7 !用 EDMP命令定义刚性体,6指约束住x和z方向，7指约束住3个旋转自由度
aLLsel,aLL
*DIM,TIME,ARRAY,2,1,1,,,
*DIM,FORC,ARRAY,2,1,1,,,
*SET,FORC(1,1,1),-FORC1
*SET,FORC(2,1,1),-FORC1
*SET,TIME(2,1,1),TT
asel,,,,3
nsla,s,1
D,aLL,,,,,,ALL,,,,,
aLLsel,aLL
asel,,,,1,6,5
nsla,s,1
D,aLL,UZ,,,,,,,,,,
aLLsel,aLL
asel,,,,2,4,2
nsla,s,1
D,aLL,UX,,,,,,,,,,
aLLsel,aLL
EPLOT
EDPART,CREATE,1,esoil
EDPART,CREATE,2,erock
EDCGEN,STS,2,1,0.00,0.00,0.0,0,0.00,,,,,0,,0,0 !定义接触参数,粘滞阻尼系数VC=sy/sqrt(3),VDC
!EDCONTACT,0.1,0,2,2,1,1,1,4,0 !接触面控制
EDHGLS,0.10
EDCSC,ON
EDLOAD,ADD,RBFY,,2,TIME,FORC,0,,,,,
EDPVEL,VELO,2,vector,-vector,,0,0,0 !定义初始速度可以采用edvel或edpvel,X方向的速度没加载成功，不知道原因？？？？？
FINISH
/SOLU
antype,trans
TIMINT,ON
TRNOPT,FULL
TIME,TT,
EDRST,DTT,
EDHTIME,DTT,
EDDUMP,1,
!/STATUS,SOLU
SOLVE
FINISH
/DSCALE,1,OFF
/REPLOT
vsel,,,,2
eslv,s
nsle,s
*get,Nrock,node,0,num,min
allsel,all
!落石运动特性与时间曲线
/POST26
NSOL,2,Nrock,U,Y,UY !块石Y方向位移的时程曲线
NSOL,3,Nrock,V,Y,VY !块石Y方向速度的时程曲线
NSOL,4,Nrock,A,Y,AY !块石Y方向加速度的时程曲线
NSOL,5,Nrock,U,X,UX !块石X方向位移的时程曲线
NSOL,6,Nrock,V,X,VX !块石X方向速度的时程曲线
NSOL,7,Nrock,A,X,AX !块石X方向加速度的时程曲线
STORE,MERGE
XVAR,1 !定义X轴变量，1代表时间，n代表所定义的变量
PLVAR,2,5
PLVAR,3,6
PLVAR,4,7
PRVAR,2,3,4
学习了！！！！！！！
页:
[1]