ansys热分析实例整理
Emp1:/GRA,POWER
/NOPR ! set preferences for menu filtering to thermal
/PMETH,OFF
KEYW,PR_SET,1 !KEYW, Keyword, KEY — Sets a keyword used by the GUI for context filtering
KEYW,PR_THERM,1
/GO !/GO — Reactivates suppressed printout
/COM,
/COM,Preferences for GUI filtering have been set to display:
/COM,Thermal!/COM, Comment — Places a comment in the output
/FILNAM,wkshop1 ! set jobname to "wkshop1"
/TITLE,Workshop 1 - Basic Heat Transfer Analysis of a Fin
/PREP7 ! enter the preprocessor
ET,1,PLANE55 ! define element type 3, PLANE55
MP,KXX,1,10, ! define material properties only KXX is required
RECTNG,0.0,0.6,0.0,0.1, ! create fin geometry using rectangle command
LSEL,S,LOC,X,0 ! select line by location x = 0
LESIZE,ALL,,,1 ! set number of division on all selectedlines to 1
ALLSEL,ALL ! select everything
LSEL,S,LOC,Y,0.1 ! select line by location, y = 0.1
LESIZE,ALL,,,12 ! set number of divisions on all selected lines to 12
ALLSEL,ALL ! select everythinghelp,amesh
LPLOT ! plot lines
MSHAPE,0,2D ! specify mapped meshing
MSHKEY,1
AMESH,ALL ! mesh all areas
FINISH ! exit the preprocessor
/SOLU ! enter solution
LSEL,S,LOC,X,0 ! select line at base on fin for temp loading
DL,ALL,,TEMP,300 ! set temperature on line to 300
ALLSEL,ALL ! select everything
LSEL,S,LOC,Y,0 ! select lower line for convection loading
LSEL,A,LOC,Y,0.1 ! select top line for convection loadingsave
SFL,ALL,CONV,0.4, ,80, ! apply convection to lines, top and bottom
ALLSEL,ALL ! select everything
SAVE ! save the databse before solution
/STAT,SOLU ! review status before solution
SOLVE ! execute solution
FINISH ! exit solution
/POST1 ! begin postprocessing
PLNSOL,TEMP, ,0, ! plot nodal solution, temperature
PATH,path1,2,30,20, ! name a path, path1 !Defines a path name and establishes parameters for the path.
PPATH,1,,0,0.1 ! define the coordinates of the first point on the path
PPATH,2,,0.6,0.1 ! define the coordinates of the second point on the path
PDEF,STAT ! review path definition
PDEF,tupper,TEMP, ,AVG ! map data onto path
PLPATH,TUPPER ! produce a path plot
PRPATH,TUPPER ! list path items
PLPAGM,TUPPER,1,'NODE' ! produce a path plot on geometry
PLNSOL,TF,X,0, ! produce plot of thermal flux in x-dir
/VSCALE,1,1,0 !PLPAGM, Item, Gscale, Nopt — Displays path items along the path geometry
PLVECT,TF, , , ,VECT,NODE,ON,0 ! produce a vector plot of flux
PRRSOL,HEAT ! list reaction solution, heat
qactual = 96.526 ! define scalar parameters
qideal = 0.4*2.0*0.6*(300-80) ! calculate q ideal
eta = qactual/qideal ! define/calculate fin efficiency
SAVE ! PLVECT, Item, Lab2, Lab3, LabP, Mode, Loc, Edge — Displays results as vectors
[ 本帖最后由 yejet 于 2006-11-13 09:10 编辑 ] Emp2
/SHO,plots,grph
/AUTO !/AUTO, WN — Resets the focus and distance specifications to "automatically calculated
/GRAP,FULL
/TYP,,4 $/COM,
/COM, Preferences for GUI filtering have been set to display:
/COM,Thermal $KEYW,PR_SET,1
!KEYW, Keyword, KEY — Sets a keyword used by the GUI for
!context filtering
KEYW,PR_THERM,1 $/FILNAM,wkshop2
/TITLE,Workshop #2 - Full Power Transistor Analysis - Steady-State
/PREP7 !*Define Geometry
RECTNG,,.01,0.03+0.01+.0025,0.03+0.01+.0025+0.0075
RECTNG,,.0225,0.03+0.01,0.03+0.01+.0025
RECTNG,,.0225,0.03,0.03+0.01
RECTNG,,.0025,,0.03
RECTNG,.0075,0.0125,,0.03
RECTNG,.0175,.0225,,0.03
AGLU,ALL
LFILLT,14,33,.0025, ,
LFILLT,33,20,0.0025, ,
LFILLT,18,34,0.0025, ,
LFILLT,34,24,0.0025, ,
AL,7,8,9
AL,10,11,33
AL,12,15,16
AL,22,23,34
ASEL,,LOC,Y,0,0.04$AADD,ALL
! KEYOPT, ITYPE, KNUM, VALUE — Sets element key options
ET,1,PLANE77 ! 2-D 8 node thermal solid elem
KEYOPT,1,1,0 ! Consistent C matrix
KEYOPT,1,3,0 ! Planar
ET,2,SURF151 ! Thermal surface effect elem
KEYOPT,2,3,0 ! Planar
KEYOPT,2,4,0 ! Include midside node
KEYOPT,2,5,1 ! Extra node for convection
KEYOPT,2,6,0 ! Extra node is fluid temp
KEYOPT,2,8,2 ! Evaluate Hf at average temp
KEYOPT,2,9,0 ! Exclude radiation
R,1 ! real set 1
R,2 ! real set 2
UIMP,1,DENS, , ,3500, ! density for material 1
UIMP,1,KXX, , ,50, ! thermal conductivity for material 1
UIMP,1,C, , ,500, ! specific heat for material 1
UIMP,2,DENS, , ,8900, ! material 2 properties
UIMP,2,KXX, , ,393, !UIMP, MAT, Lab1, Lab2, Lab3, VAL1, VAL2, VAL3
UIMP,2,C, , ,385, !Defines constant material properties (GUI)
UIMP,3,DENS, , ,2700, ! material 3 properties
UIMP,3,KXX, , ,156,
UIMP,3,C, , ,963,
ASEL,,LOC,Y,0.0425,0.05 ! assign attributes to area 1
AATT,1,1,1
ASEL,,LOC,Y,0.04,0.0425 ! assign attributes to area 2
AATT,2,1,1
ASEL,,LOC,Y,0,0.04 ! assign attributes to area 3
AATT,3,1,1
SMRT,3 ! set smart size level 3
ALLSEL ! select everything
AMES,ALL ! mesh all areas
LSEL,R,EXT ! select external lines
LSEL,R,LOC,X,.001,1 ! reselect lines by location
LSEL,R,LOC,Y,-1,.042
NSLL,,1 ! select nodes attached to lines
ESLN ! select elements attached to selected nodes
N,5000,,-0.01 ! define node 5000
TYPE,2 $ REAL,2 ! set meshing attributes to type 2, real 2
!ESURF — Generates elements overlaid on the free faces of existing selected elements.
ESURF,5000 ! create surf151 elem, extra node is 5000
ALLSEL ! select everything
SAVE,transistor,db ! save the database as transistor.db
SAVE ! save the database as jobname.db
/SOLUTION !BFA, AREA, Lab, VAL1, VAL2, VAL3, PHASE — Defines a body force load on an area.
BFA,1,HGEN,5333334 ! Apply heat generation to transistor
SFL,2,HFLUX,1500 ! Apply heat flux to lines
SFL,30,HFLUX,1500 ! Apply heat flux to lines
SFL,3,HFLUX,1500
ESEL,,TYPE,,2 ! Select surf. Effect elements
SFE,ALL,1,CONV,,51 ! ApplyConv. to Surf. Eff. Elem.
ALLSEL
D,5000,TEMP,50 ! Extra node fixed at ambient temp
/PBC,TEMP,1 !!*Visually verify loads
/PBF,HGEN,,1 !/PSF, Item, Comp, KEY, KSHELL — Shows surface load symbols on model displays
/PSF,CONV,2 $EPLO
SAVE$SOLVE$FINISH $/POST1
ESEL,S,TYPE,,1 ! select all type 1 ,PLANE77 elements
ALLSEL,BELOW,ELEM
! select everything below the selected elements
NSLE,S ! select nodes attached to elements
PLNSOL,TEMP, ,0, ! plot nodal solution, temperature
NSORT,TEMP, ,0,0,_Z3,0 ! sort nodes based on temperature
PRNSOL,TEMP, ! print sorted list
NUSORT ! unsort nodes
/ZOOM,1,RECT,-0.554972,0.504832,0.183702,0.968805
! zoom up on hot areas
/GRAPHICS,FULL ! turn power graphics off
ALLSEL,ALL ! select everything
PRRSOL,HEAT ! print reaction solution, heat flow rate
NSEL,S,TEMP,,100,106, ,0 ! select nodes by results, temperature
NPLOT ! plot nodes for checking
ESLN,S ! select elements attached to nodes
EPLOT ! plot elements for checking/viewing
PLNSOL,TEMP, ,0, ! plot nodal solution, temperature
/AUTO, 1 $/REP
ALLSEL,ALL ! select everything
/VSCALE,1,1,0 ! set scaling of vectors for vector plot
PLVECT,TF, , , ,VECT,ELEM,ON,0! produce thermal flux plot
/VSCALE,1,1,0 ! set scaling of vectors for vector plot
PLVECT,TG, , , ,VECT,ELEM,ON,0! produce thermal gradient plot
/EXPAND,2,RECT,HALF,0.00001 ! expand results
ESEL,S,TYPE,,1 ! select all type 1 elements
ALLSEL,BELOW,ELEM ! select everything below the selected elements
NSLE,S ! select nodes attached to elements
PLNSOL,TEMP,,0, ! plot nodal solution, temperature
FINISH ! exit the postprocessor Emp3:
/SHO,plots3,grph
/AUTO $/GRAP,FULL
/TYP,,4 $/COM,
/COM, Preferences for GUI filtering have been set to display:
/COM,Thermal
KEYW,PR_SET,1
KEYW,PR_THERM,1
/TITL, Nonlinear Thermal Analysis of a Transistor
/PREP7 !*Define Geometry
RECTNG,,.01,0.03+0.01+.0025,0.03+0.01+.0025+0.0075
RECTNG,,.0225,0.03+0.01,0.03+0.01+.0025
RECTNG,,.0225,0.03,0.03+0.01
RECTNG,,.0025,,0.03
RECTNG,.0075,0.0125,,0.03
RECTNG,.0175,.0225,,0.03
AGLU,ALL
LFILLT,14,33,.0025, ,
LFILLT,33,20,0.0025, ,
LFILLT,18,34,0.0025, ,
LFILLT,34,24,0.0025, ,
AL,7,8,9
AL,10,11,33
AL,12,15,16
AL,22,23,34
ASEL,,LOC,Y,0,0.04
AADD,ALL
ET,1,PLANE77 ! 2-D 8 node thermal solid elem
KEYOPT,1,1,0 ! Consistent C matrix
KEYOPT,1,3,0 ! Planar
ET,2,SURF151 ! Thermal surface effect elem
KEYOPT,2,3,0 ! Planar
KEYOPT,2,4,0 ! Include midside node
KEYOPT,2,5,1 ! Extra node for convection
KEYOPT,2,6,0 ! Extra node is fluid temp
KEYOPT,2,8,2 ! Evaluate Hf at average temp
KEYOPT,2,9,0 ! Exclude radiation
R,1 $R,2
UIMP,1,DENS, , ,3500,
UIMP,1,KXX, , ,50,
UIMP,1,C, , ,500,
UIMP,2,DENS, , ,8900,
UIMP,2,KXX, , ,393,
UIMP,2,C, , ,385,
UIMP,3,DENS, , ,2700,
UIMP,3,KXX, , ,156,
UIMP,3,C, , ,963,
ASEL,,LOC,Y,0.0425,0.05
AATT,1,1,1
ASEL,,LOC,Y,0.04,0.0425
AATT,2,1,1
ASEL,,LOC,Y,0,0.04
AATT,3,1,1
SMRT,3
ALLSEL
AMES,ALL
LSEL,R,EXT
LSEL,R,LOC,X,.001,1
LSEL,R,LOC,Y,-1,.042
NSLL,,1
ESLN
N,5000,,-0.01
TYPE,2
REAL,2
ESURF,5000
ALLSEL
SAVE,transistor,db
/COM, Input Temp-Dependent Thermal Cond Properties
MPTGEN,1,4,50,50,
MPDATA,KXX,1,1,53,52,47,41, , ,
MPPLOT,KXX,1,,,,,
/COM, Input Temp-Dependent Film Properties
MPTEMP,1,50,75,100,150,175,200
MPDATA,HF,4,1,18.8,17.0,16.3,14.4,12.4,6.5,
MPPLOT,HF,4,,,,,
FINI $/SOLUTION
SOLCONTROL,ON ! Default at ANSYS 5.5
ANTYPE,0 ! New Static analysis
TUNIF,100 ! Uniform ambient starting temperature
BFA,1,HGEN,5333333 ! Apply heat generation to transistor
/COM,Apply Radiative Heat Flux to Lines
SFL,2,HFLUX,2400
SFL,30,HFLUX,2400
SFL,3,HFLUX,2400
ESEL,,TYPE,,2 ! Select surf. Effect elements
SFE,ALL,1,CONV,,(-4) ! Apply Free Conv. to Surf. Eff. Elem.
ALLSEL
D,5000,TEMP,60 ! Extra node fixed at hotter ambient temp
!*Visually verify loads
/PBC,TEMP,1
/PBF,HGEN,,1
/PSF,CONV,2
EPLO
OUTRES,ALL,ALL ! Write results at all times for all entities
TIME,1 ! Time at end of load step = 1 second
AUTOTS,-1 ! Program Chosen ATS
NSUB,10 ! Initial number of substeps
KBC,0 ! Ramp loads
CNVTOL,HEAT, ,0.0001,2 ! Tighten convergence criterion
/TITL, Transistor Cooled by Free Convection
SAVE
SOLVE
FINISH
/POST1
SET,LIST ! Results summary listing
SET,LAST ! Bring in last results set
ESEL,,TYPE,,1
NSLE
PLNS,TEMP ! Temperature plot
ESEL,,TYPE,,2
ETABLE, ,NMISC, 5
ETABLE, ,NMISC, 7
PRETAB
ESEL,,TYPE,,1
NSLE
SET,1,3 ! Bring in results at failure point (t=0.35)
PLNS,TEMP ! Temperature plot
ALLSEL $FINI Emp4:
/SHO,plots4,grph
/AUTO$/GRAP,FULL
/TYP,,4$/COM,
/COM, Preferences for GUI filtering have been set to display:
/COM,Thermal
KEYW,PR_SET,1
KEYW,PR_THERM,1
/TITLE, Transient Thermal Analysis of a Transistor
/PREP7 !*Define Geometry
RECTNG,,.01,0.03+0.01+.0025,0.03+0.01+.0025+0.0075
RECTNG,,.0225,0.03+0.01,0.03+0.01+.0025
RECTNG,,.0225,0.03,0.03+0.01
RECTNG,,.0025,,0.03
RECTNG,.0075,0.0125,,0.03
RECTNG,.0175,.0225,,0.03
AGLU,ALL
LFILLT,14,33,.0025, , $LFILLT,33,20,0.0025, ,
LFILLT,18,34,0.0025, ,$LFILLT,34,24,0.0025, ,
AL,7,8,9 $AL,10,11,33
AL,12,15,16$AL,22,23,34
ASEL,,LOC,Y,0,0.04
AADD,ALL
ET,1,PLANE77 ! 2-D 8 node thermal solid elem
KEYOPT,1,1,0 ! Consistent C matrix
KEYOPT,1,3,0 ! Planar
ET,2,SURF151 ! Thermal surface effect elem
KEYOPT,2,3,0 ! Planar
KEYOPT,2,4,0 ! Include midside node
KEYOPT,2,5,1 ! Extra node for convection
KEYOPT,2,6,0 ! Extra node is fluid temp
KEYOPT,2,8,2 ! Evaluate Hf at average temp
KEYOPT,2,9,0 ! Exclude radiation
R,1 $R,2
UIMP,1,DENS, , ,3500, $UIMP,1,KXX, , ,50,
UIMP,1,C, , ,500, $UIMP,2,DENS, , ,8900,
UIMP,2,KXX, , ,393, $UIMP,2,C, , ,385,
UIMP,3,DENS, , ,2700, $UIMP,3,KXX, , ,156,
UIMP,3,C, , ,963,
ASEL,,LOC,Y,0.0425,0.05$AATT,1,1,1
ASEL,,LOC,Y,0.04,0.0425 $AATT,2,1,1
ASEL,,LOC,Y,0,0.04
AATT,3,1,1 $SMRT,3
ALLSEL$AMES,ALL
LSEL,R,EXT $LSEL,R,LOC,X,.001,1
LSEL,R,LOC,Y,-1,.042
NSLL,,1 $ESLN $N,5000,,-0.01
TYPE,2 $REAL,2
ESURF,5000 $ALLSEL $FINI
SAVE,transistor,db
/SOLUTION
SOLCONTROL,ON ! Default at ANSYS 5.5
ANTYPE,4 ! New Transient analysis
TRNOPT,FULL ! Use full method
EQSLV,ITER,5 ! automatic solver and direct assembly
TUNIF,50 ! Uniform ambient starting temperature
BFA,1,HGEN,2666667 ! Apply heat generation to transistor
/COM,Apply Radiative Heat Flux to Lines
SFL,2,HFLUX,1500 $SFL,30,HFLUX,1500
SFL,3,HFLUX,1500
ESEL,,TYPE,,2 ! Select surf. Effect elements
SFE,ALL,1,CONV,,30 ! Apply LP Fan Conv. to Surf. Eff. Elem.
ALLSEL
D,5000,TEMP,50 ! Constrain extra node temp to ambient temp
!*Visually verify loads
/PBC,TEMP,1 $/PBF,HGEN,,1
/PSF,CONV,2 $EPLO
OUTRES,ALL,ALL ! Write results at all times for all entities
TIME,1 ! Time at end of load step = 1 second
AUTOTS,-1 ! Program Chosen ATS
DELTIM,.01,.0025,60,0 ! INITIAL, MIN, MAX time step
KBC,0 ! Ramp loads
!KBC, KEY — Specifies stepped or ramped loading within a load step
TINTP,,,,0.75,0.5,0.1 ! THETA=0.75, OSC=0.5, TOL=0.1
!TINTP— Defines transient integration parameters.
/COM, MONITOR,3,5000,HEAT! Does not work at 5.5.1
SAVE,tabular,db
/TITL, LS 1 - Transistor Activation (1 second)
SAVE $SOLVE
TIME,300 ! Time at end of load step = 300 seconds
/TITL, LS 2 - Low Power Operation (300 seconds)
SOLVE
/TITL, LS 3 - High Power Load Ramp (302 seconds)
SFSCALE,CONV,1.7 ! Scale convection hf by 1.7 for high power
BFA,1,HGEN,2666667*2 ! Transistor heat generation
TIME,302 ! Time at end of load step = 302 seconds
SOLVE
/TITL, LS 4 - High Power Operation (900 seconds)
TIME,900 ! Time at end of load step = 900 seconds
SOLVE
/TITL, LS 5 - High Power Operation - Steady State
AUTOTS,OFF ! Turn off automatic time stepping
NSUB,1 ! one substep
TIME,1000 ! Time at end of load step = 1000 seconds
TIMINT,OFF ! Turn off time integration
SOLVE $FINISH $/POST1
SET,2 ! Bring in results at time = 300 seconds
ESEL,,TYPE,,1 $NSLE
PLNS,TEMP ! Temperature plot
ALLSEL
SET,5 ! Bring in steady state results
PRRS ! List reaction heat flow
FINISH $/POST26
/TITL,
KSEL,,,,KP(0.01,0.05,0)
NSLK
*GET,N1,NODE,,NUM,MAX ! High Temp Node Number
ALLSEL
NSOL,2,N1,TEMP, ,TEMP_MAX! Max temp variable
SOLU,3,DTIME, ,TIME_STP ! Time step variable
SOLU,4,RESEIG, ,RESP_EIG ! Response eigenvalue
PROD,5,3,4, ,OSC, , ,1,1,1,! Calculate oscillation limit
/COM, Calculate lumped mass approximation
FILLDATA,7,1, ,1,94.144,0,
EXP,8,1, , ,TERM1, , ,-.002655,-44.144,
ADD,9,7,8, ,CALC_10W, , ,1,1,1,
FILLDATA,10,1,,1,97.165,0
! Steady-state High Power Temperature line
/GTHK,CURVE,2
/GRID,1
/AXLAB,X,Time (s)
/GTHK,AXIS,2!/GTHK, Label, THICK — Sets line thicknesses for graph lines.
/GROPT,AXDV,1 !GROPT, Lab, KEY — Sets various line graph display options
/GROPT,AXNM,ON
/GROPT,AXNSC,1,
/GROPT,DIG1,4,
/GROPT,DIG2,0,
/GROPT,LTYP,1
/XRANGE,0,1000 !/XRANGE, XMIN, XMAX — Specifies a linear abscissa (X) scale range
/YRANGE,DEFAULT,,1
/AXLAB,Y,Temperature (C) !/AXLAB, Axis, Lab — Labels the X and Y axes on graph displays.
PLVAR,2,9,10 ! Plot Max T, Calc T, and SS T variables
PRVAR,3 ! List time step variable
/AXLAB,Y,Oscillation Limit
PLVAR,5 ! Plot Oscillation limit variable
Fini Emp5:
! Transient Thermal Analysis of a Transistor - Tabular Loads
!TRANSIENT ANALYSIS OF TRANSISTOR USING TABULAR LOADS
!STARTING FROM tabular.db CREATED IN WORKSHOP 4
!tabular.db HAS SOLID MODEL, FEA MODEL, ALL LOADS FOR
!FIRST LOAD STEP, TRANSIENT ANALYSIS DEFINED, INITIAL T,
!SOLUTION CONTROLS ON, ITERATIVE SOLVER, OUTPUT CONTROLS,
!DELTIM, AND TIME INTEGRATION CONTROLS DEFINED
RESUME,tabular,db
!INTO THE SOLUTION PROCESSOR
/SOLU
!DELETE LOADS CURRENTLY APPLIED TO THE MODEL
BFADELE,ALL,ALL
! REMOVES THE HEAT GENERATION ON AREAS
SFLDELE,ALL,ALL! REMOVES RADIATION FLUX ON LINES
!BFADELE, AREA, Lab — Deletes body force loads on an area
SFEDELE,ALL,ALL,ALL !REMOVES THE Hf DEFINITION FOR THE
!SURFACE EFFECT ELEMENTS BUT LEAVES
!HE Tb DEFINITION(50 degrees) ON
!THE EXTRA NODE(NODE NUMBER 5000)
*DIM,TIMESET,ARRAY,3 !DEFINE ARRAY FOR TIME STEP RESET
TIMESET(1)=1.0,300,302
*DIM,HEATGEN,TABLE,5,TIME
! DEFINE TABLE FOR HEAT GEN.=F(T)
HEATGEN(1,0)=1.E-6,1.0,300,302,900
HEATGEN(1,1)=0.0,2666667,2666667,2*2666667,2*2666667
*DIM,CONVHF,TABLE,5,TIME ! DEFINE TABLE FOR Hf=G(T)
CONVHF(1,0)=1.E-6,1.0,300,302,900
CONVHF(1,1)=30,30,30,51,51
*DIM,HEATFLX,TABLE,3,TIME
! DEFINE TABLE FOR HFLUX=Q(T)
HEATFLX(1,0)=1.E-6,1.0,900
HEATFLX(1,1)=0.0,1500,1500
/TITLE,Transistor Analysis Using Tabular Input
TIME,900
!DEFINE COMPONENTS(NOT NECESSARY), APPLY TABULAR BCS
!TO THE COMPONENTS
ASEL,S,AREA,,1 ! SELECT TRANSISTOR AREA
ALLSEL,BELOW,AREA
! SELECT ELEMENTS ASSOCIATED WITH AREA
CM,TRANAREA,ELEMENT
!CM, Cname, Entity — Groups geometry items into a component
ALLSEL,ALL
LSEL,S,LINE,,2,3,1 ! SELECT LINES FOR RADIATION FLUX
LSEL,A,LINE,,30
CM,FLUXLINE,LINE ! CREATE COMPONENT
ESEL,S,ENAME,,SURF151
! SELECT ELEMENTS FOR CONVECTION
CM,CONVELEM,ELEMENT ! CREATE COMPONENT
ALLSEL,ALL
!APPLY LOADS USING COMPONENT NAMES
BFE,TRANAREA,HGEN,1,%HEATGEN%
! HEAT GENERATION
SFL,FLUXLINE,HFLUX,%HEATFLX% ! RADIATION FLUX
SFE,CONVELEM,1,CONV,,%CONVHF% ! CONVECTION HF
!FORCE TIME STEP RESET AT LOAD CHANGE POINTS
TSRES,%TIMESET% $SOLVE
FINISH $/POST26
KSEL,,,,KP(0.01,0.05,0) $NSLK
*GET,N1,NODE,,NUM,MAX
NSOL,2,N1,TEMP,,TEMP_MAX
FINI Emp6:
! ANSYS 5.5 Heat Transfer Seminar Notes! Workshop #6
! Low Pressure Gas Turbine Case Thermal Analysis
! MUST HAVE case.db AND work6excel.txt TO RUN
RESUME,case,db ! Supplied with seminar files
/TITLE, Low Pressure Gas Turbine Case Thermal Analysis
!*SET PREFERENCES TO THERMAL AND FLUID/PMETH,OFF
KEYW,PR_SET,1 $KEYW,PR_THERM,1
KEYW,PR_FLUID,1 $KEYW,PR_MULTI,1
/COM,
/COM,Preferences for GUI filtering have been set to display:
/COM,Thermal$/COM,ANSYS Fluid
/PREP7!DEFINE THE SURF151 AND FLUID116 TYPES
ET,2,SURF151 $ET,3,FLUID116
KEYOPT,2,3,1 $KEYOPT,2,4,1
KEYOPT,2,5,1 ! KEYOPTIONS FOR SURF151s
KEYOPT,2,6,0 $KEYOPT,2,8,2
KEYOPT,2,9,0
KEYOPT,3,1,1 ! KEYOPTIONS FOR FLUID116s
KEYOPT,3,2,1 $ETLIST, ALL
MPLIST ! LIST PREDEFINED TEMP-DEPENDENT MPs
! REAL SET FOR FLUID116
PI=ACOS(-1) $R,2
R,3,,1E-6, ! Diameter, area, # channels
!CREATE KEYPOINTS 112,113,114 ON WP
K,,16.7628783879,145.253628512,0
K,,16.4392239406,146.100950574,0
K,,16.6407907696,147.310654059,0
!CREATE LINES FOR FLUID ELEMENTS
LSTR, 112, 113$LSTR, 113, 114
!SET ELEMENT ATTRIBUTES FOR THE LINES
LSEL, , , ,91,92$LATT,20,3,3,0, , ,
!SET ELEMENT DIVISIONS TO ONE FOR
!FLUID LINES
LESIZE,ALL, , ,1,1
!MESH LINES WITH FLUID116
LMESH,ALL $CMLIST
! LIST PREDEFINED LINE COMPONENTS
!CREATE SUR151S FOR ZONE 101
CMSEL,S,LZONE101
LPLOT$NSLL,S,1$NPLOT
TYPE,2$MAT,1 $REAL,2
ESURF,380 ! NODE 380 IS POINT A AND EXTRA NODE
ESEL,R,ENAME,,151
!CREATE A COMPONENT FOR SURF151 ON ZONE101
CM,SURF101,ELEM
ESEL,ALL $ESEL,U,TYPE,,2
! REPEAT FOR ZONE 102
CMSEL,S,LZONE102
LPLOT $NSLL,S,1$NPLOT
ESURF,380 $ESEL,R,TYPE,,2
CM,SURF102,ELEM
ESEL,ALL $ESEL,U,TYPE,,2
!REPEAT FOR ZONE 103
CMSEL,S,LZONE103
LPLOT$NSLL,S,1$NPLOT
ESURF,381 ! NODE 381 IS AT POINT B
ESEL,R,TYPE,,2 $CM,SURF103,ELEM
ESEL,ALL $ESEL,U,TYPE,,2
CMSEL,S,LZONE104
NSLL,S,1$ NPLOT
!NSLL,Type,NKEY , Selects those nodes associated with the selected lines
ESURF,382 ! NODE 382 IS AT POINT C
ESEL,R,TYPE,,2 $CM,SURF104,ELEM
ESEL,ALL$NSEL,ALL
!DIMENSION THE TABLE FOR HF FOR ZONE104
*DIM,HF104,TABLE,4,5,1,TIME,Y,
!READ IN THE EXCEL SPREADSHEET
*TREAD,HF104,work6excel,txt,,4,
ALLSEL,ALL $LPLOT
!SELECT THE LINES WHERE COUPLING IS NEEDED
FLST,5,8,4,ORDE,8
!FLST,NFIELD,NARG,TYPE,Otype,LENG
!Specifies data required for a picking operation .
FITEM,5,16 !FITEM,NFIELD,ITEM,ITEMY,ITEMZ—Identifies items chosen by a picking operation
FITEM,5,29$FITEM,5,41$FITEM,5,57$FITEM,5,60
FITEM,5,80$FITEM,5,88$FITEM,5,-89
LSEL,S, , ,P51X !CREATE COMPONENT OF LINES AT INTERFACE
CM,LINTERFA,LINES$/REPLOT
NSLL,S,1 $NPLOT
!CHECK THE DISTANCE BETWEEN NODES TO
!SET TOLERANCE FOR COUPLING
NDISTANCE,136,15 !CREATE THE COUPLING EQUATIONS
CPINTF,TEMP,0.005, $ALLSEL,ALL
FINI$/SOLUTION$SOLCONTROL,ON,0
!SELECT COMPONENT SURF101
CMSEL,S,SURF101
SFE,ALL,1,CONV, , %HF101%! APPLY TABULAR Hf
SFE,ALL,1,CONV,2, !SELECT COMPONENT SURF102
CMSEL,S,SURF102
SFE,ALL,1,CONV, , %HF102%! APPLY TABULAR Hf
SFE,ALL,1,CONV,2, !SELECT COMPONENT SURF103
CMSEL,S,SURF103
SFE,ALL,1,CONV, , %HF103%! APPLY TABULAR Hf
SFE,ALL,1,CONV,2, !SELECT COMPONENT SURF104
CMSEL,S,SURF104
SFE,ALL,1,CONV, , %HF104%! APPLY TABULAR Hf
SFE,ALL,1,CONV,2,
!SELECT COMPONENT LZONE105 (LINES IN ZONE105)
CMSEL,S,LZONE105 !APPLY TABULAR Hf AND Tb
SFL,ALL,CONV, %HF105% , , %TB05T09%
!SELECT COMPONENT LZONE106
CMSEL,S,LZONE106 !APPLY TABULAR Hf AND Tb
SFL,ALL,CONV, %HF106% , , %TB05T09%
!SELECT COMPONENT LZONE107
CMSEL,S,LZONE107 !APPLY TABULAR Hf AND Tb
SFL,ALL,CONV, %HF107% , , %TB05T09%
!SELECT COMPONENT LZONE108
CMSEL,S,LZONE108 !APPLY TABULAR Hf AND Tb
SFL,ALL,CONV, %HF108% , , %TB05T09%
!SELECT COMPONENT LZONE109
CMSEL,S,LZONE109 !APPLY TABULAR Hf AND Tb
SFL,ALL,CONV, %HF109% , , %TB05T09%
ALLSEL,ALL !DEFINE TABLE ARRAYS FOR INLET FLUID
!TEMPERATURE AND MASS FLOW RATES
!IN THE TWO FLUID116S
*DIM,TINLET,TABLE,4,1,1,TIME, ,
*DIM,FLOWAB,TABLE,4,1,1,TIME, ,
*DIM,FLOWBC,TABLE,4,1,1,TIME, ,
TINLET(1,0,1) = 0 $TINLET(1,1,1) = 304.33
TINLET(2,0,1) = 3 $TINLET(2,1,1) = 870.33
TINLET(3,0,1) = 160$TINLET(3,1,1) = 870.33
TINLET(4,0,1) = 163$TINLET(4,1,1) = 304.33
FLOWAB(1,0,1) = 0 $FLOWAB(1,1,1) = 0.001
FLOWAB(2,0,1) = 3 $FLOWAB(2,1,1) = 0.0042
FLOWAB(3,0,1) = 160$FLOWAB(3,1,1) = 0.0042
FLOWAB(4,0,1) = 163$FLOWAB(4,1,1) = 0.001
FLOWBC(1,0,1) = 0 $FLOWBC(1,1,1) = 0.000692
FLOWBC(2,0,1) = 3 $FLOWBC(2,1,1) = 0.002908
FLOWBC(3,0,1) = 160$FLOWBC(3,1,1) = 0.002908
FLOWBC(4,0,1) = 163$FLOWBC(4,1,1) = 0.000692
LPLOT $/AUTO, 1 $/REP
!SPECIFY INLET FLUID TEMPERATURE
!AT NODE 380 AS TABULAR INPUT
D,380,TEMP,%TINLET%
!SPECIFY MASS FLOW RATE ON FLUID116
!FROM A TO B, USING HFLUX
SFE,252,,HFLUX, ,%FLOWAB%
SFELIS,252,HFLUX!SPECIFY MASS FLOW RATE FROM B TO C
SFE,253,,HFLUX, ,%FLOWBC%$SFELIS,253,HFLUX
ANTYPE,0 ! ANALYSIS TYPE STEADY-STATE
TIME,1.E-6 ! TIME AT END OF STEADY-STATE
NSUB,1 ! ONE SUBSTEP
ALLSEL
SOLVE ! RUN STEADY-STATE
SAVE ! SAVE THE DATABASE FOR RESTART
FINISH $/POST1
PLNSOL,TEMP ! REVIEW THERMAL CONTOURS
FINISH $RESUME $/SOLU
ANTYPE,,REST$TIMINT,ON
!DT_START = DX**2/(10 x ALPHA) = 0.05 seconds
DELTIM,0.05,0.005,10,0
KBC,0 ! RAMP LOADS
TIME,163
!DEFINE THE ARRAY TO USE FOR TIME STEP SIZE RESET
*DIM,TSTEP,ARRAY,2,1,1, , ,
TSTEP(1,1,1)=3 $TSTEP(2,1,1)=160
TSRES,%TSTEP% ! USE TSTEP ARRAY
OUTRES,NSOL,ALL$SAVE
SOLVE $FINI Emp7:
/filn,stltube ! db created in Ch. 3 (ch3_ex.inp will create)
RESU
/PREP7
ACLEAR,ALL ! Clear thermal mesh
EDEL,ALL ! Delete surface effect elements
NDEL,ALL ! Delete extra node
ETDEL,1 ! Delete element type 1 (thermal solids)
ETDEL,2 ! Delete element type 2 (surface effect elements)
FINISH$/SOLU
LSCLEAR,ALL ! Clear all thermal loads
FINISH
/filn,stress ! Change jobname to STRESS
/PREP7
/TITL, THERMAL-STRESS ANALYSIS OF STEEL TUBE WITH FINS
/NOPR!/NOPR,Suppresses the expanded interpreted input data listing.
/PMETH,OFF
KEYW,PR_SET,1 !KEYW,Keyword,KEY—Sets a keyword used by the GUI for context filtering
KEYW,PR_STRUC,1$KEYW,PR_THERM,1
KEYW,PR_MULTI,1
/GO $/COM,
/COM,Preferences for GUI filtering have been set to display:
/COM,Structural $/COM,Thermal
ET,1,PLANE82 ! 8 node structural planar solid
KEYOPT,1,3,1 ! Axisymmetric option
!INPUT Structural MPs
UIMP,1,EX, , ,28E6 $UIMP,1,DENS, , ,0.00073
UIMP,1,ALPX, , ,5E-6 $UIMP,1,NUXY, , ,0.3
!Add 0.075 Fillet Radius in Corner
LFILLT,12,15,.075$AL,2,4,5
AADD,ALL $NUMC,ALL
TYPE,1 $MAT,1$REAL,1
SMRT,3 $MSHKEY,0
AMESH,ALL ! Mesh model
NWRITE ! Write node file (stltube.nod)
SAVE $FINI
/FILN,stltube ! Resume thermal model
RESU$ALLSEL$/POST1
SET,LAST ! Read in thermal results set
BFINT,stress,node,,,,,0,,0,1 ! Perform body load interp.
FINI$/FILN,stress ! Resume structural model
RESU$ALLSEL $/SOLU
/INPUT,stltube,bfin,,,0 ! Read in body load temps (stltube.bfin)
/PBF,TEMP,1 $EPLO ! Check temperature loads
! Specify Analysis Settings and Other Loads
ANTYPE,0$TREF,70
OMEGA,,2500, $DL,1, ,SYMM
DL,8, ,SYMM $DL,3, ,SYMM
SFL,5,PRES,1500 $SFL,7,PRES,1500
SAVE $SOLVE $FINI
! POSTPROCESS WITH TEMPS
/POST1
PLNS,S,EQV $PLES,SDSG
PLNS,EPTH,Z$PLNS,EPEL,Z
FINI $/SOLU
ANTY,,REST !Restart Solution and run w/o Temps
BFDELE,ALL,TEMP
/TITL, NO TEMPERATURE LOAD
SOLVE $FINI
!POSTPROCESS W/O TEMPS
/POST1 SET,LAST $PLNS,BFE,TEMP
PLNS,S,EQV$FINI 楼主能不能说下做的什么热分析 我也是感觉这么好的例子应该有些说明，当然了，大家谁知道的可以写下自己的理解
有奖励哟 是呀，感觉看起来好累。谁有时间看1遍再运行一下，把说明和注释加上就好了。 我也觉得楼主如果能够做一下这些例子的相关介绍就更好了，很感谢楼主的分享！ 感谢楼主，但没有文字说明，还是感到有点麻烦。 请问楼主有没有LS-DYNA的热分析例子啊，大哥们知不知道我下面这段热分析命令是什么问题啊，分析时总是显示
The LS-DYNA time step size should not exceed 0.651E-06
to avoid contact instabilities.If the step size is
bigger then scale the penalty of the offending surface.
time step larger than problem time
热分析时间设置
*CONTROL_THERMAL_TIMESTEP
1 1.0 5.0 0 0 20.0
*CONTROL_CONTACT
5 1
*CONTROL_SOLUTION
2
*CONTROL_THERMAL_NONLINEAR
10 0.0 0.5
*CONTROL_THERMAL_SOLVER
1 0 3 1E-4 0 1 0.9
*CONTROL_THERMAL_TIMESTEP
1 1.0 5.0 0 0 20.0
*INITIAL_TEMPERATURE_SET
10 20
11 20
*SET_NODE_GENERAL
10
PART 1
*SET_NODE_GENERAL
11
PART 2
*BOUNDARY_TEMPERATURE_SET
10 0 20
*BOUNDARY_TEMPERATURE_SET
11 0 20
************************************
*MAT_THERMAL_ISOTROPIC（钢）
1 7.80E+6 0 0
480 4.62
*********************************
*CONTROL_TIMESTEP
0.0000 0.9000 00.00 0.00
*CONTROL_TERMINATION
0.500E-03 0 0.00000 0.00000 0.00000
$
$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
$ TIME HISTORY $
$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
$
*DATABASE_BINARY_D3PLOT
0.5000E-06
*DATABASE_BINARY_D3THDT
0.100E-07 期待大侠整理一下
附加点说明 呵呵，资料是很不错，不过要是能给每个例子附加上一个简短的说明就好了，至少说明一下所给出例题的模型是怎么样的，不然看起来就太费劲了呀。