请教一下压电悬臂梁的瞬态响应分析（附APDL）
这是压电悬臂梁模型这是g加速度下的谐响应分析得到的输出电压的结果。
然后施加单一频率的正弦加速度激励a=sin(40*6.28*t)做瞬态响应分析, 如果正确的话输出电压图形随时间应该是在1-2秒内达到一个稳态，而不是像下图所示的情况。
这样的情况才是正确的，但是我不知道错误在什么地方，希望有人可以帮忙指正一下。感激不尽。
下面附上程序
!双压电晶片串联：中间相对两个面接地，两位两个面为正负极
FINISH
/CLEAR,START
/prep7
*SET,R1,1E-10 ! 电阻值取足够时，相当于导线
*SET,R2,1E3 !!!负载电阻
!定义材料类型
et,1,solid5,3 !定义压电单元
et,2,solid45 !定义主结构单元
ET,3,CIRCU94 ! 电路单元
R,1,R1,
R,2,R2,
! PZT-5H 材料特性参数
mp,DENS,1,7450 ! 密度, kg/m^3
EMUNIT,EPZRO,8.854E-12 !介电常数
MP,PERX,1,1.730E3
MP,PERY,1,1.730E3
MP,PERZ,1,1.700E3
tb,ANEL,1 ! 弹性劲度系数, N/m^2
tbdata,1,12.1E10,7.54E10,7.52E10! c11,c12,c13
tbdata,7,12.1E10,7.52E10 ! c11,c13
tbdata,12,11.1E10 ! c33
tbdata,16,2.26E10 ! c66
tbdata,19,2.11E10 ! c44
tbdata,21,2.11E10 ! c44
tb,PIEZ,1 ! 压电（应力）常数, C/m^2
TBDATA,3,-5.4
TBDATA,6,-5.4
TBDATA,9,15.8
TBDATA,14,12.3
TBDATA,16,12.3
!定义主结构的材料参数
mp,dens,2,8920
mp,EX,2,113e9
mp,nuxy,2,0.33
!MP,DAMP,2,,0.027
!定义质量块的材料参数
mp,dens,3,8984.7
mp,EX,3,113E9
mp,nuxy,3,0.33
! 定义压电复合梁几何模型
L=50.8e-3
b=30.8e-3
Hp=0.26e-3 !压电片几何尺寸
Hs=0.15e-3 !主结构几何尺寸
h0=6e-3 !物块
L0=7e-3
local,11,,,,0.02+Hs ! 建立下层局部坐标 +Z 方向
local,12,,,,0.02+Hs,,,180! 建立上层局部坐标 -Z 方向
local,13,,L,-b/2,0.02-h0/2,,,,
csys,11 ! 激活局部坐标系11 +z 方向
block,0,L,-b/2,b/2,0.02-Hp,0.02
block,0,L,-b/2,b/2,0.02,Hs+0.02
block,0,L,-b/2,b/2,Hs+0.02,Hs+Hp+0.02
block,L,L+L0,-b/2,b/2,0.02-h0/2,0.02+h0/2
vglue,all
NUMCMP,all
!进行网格划分
LESIZE,ALL,1e-3, , , ,1, , ,1,
mat,2 $ type,2 $ esys,11!对中间结构网格划分
Vsweep,2
allsel
mat,3 $ type,2 $ esys,11
vsweep,4
allsel
mat,1 $ type,1 $ esys,11!对上层压电片网格划分设置元素的材料属性指针
Vmesh,3
allsel
mat,1 $ type,1 $ esys,12!对下层压电片网格划分
vmesh,1
allsel
NUMMRG,NODE
NSEL,ALL
NUMCMP,NODE
nsel,s,loc,z,-(Hp+Hs) !定义下层电极(选择节点的位置与激活坐标系有关)
nsel,r,loc,x,0,L
*get,n_bot,node,0,num,min
cp,n_bot,volt,all
allsel
nsel,s,loc,z,Hp !定义上层电极
nsel,r,loc,x,0,L
*get,n_top,node,0,num,min
cp,n_top,volt,all
allsel
TYPE,3 !电阻R2
REAL,2
E,n_top,n_bot
allsel
ASEL,S,LOC,Z,-Hs !中间导线连接，接地
nsel,R,loc,z,-Hs
nsel,r,loc,x,0,L
*GET,CM_3,NODE,,NUM,min
cp,CM_3,volt,all
allsel
ASEL,S,LOC,Z,0
nsel,R,loc,z,0
nsel,r,loc,x,0,L
*GET,Cm_4,NODE,,NUM,min
cp,CM_4,volt,all
allsel
TYPE,3 !电阻R1
REAL,1
E,CM_3,Cm_4
NSEL,S,NODE,,CM_3
D,CM_3,VOLT,0
allsel
!定义约束
ASEL,S,LOC,X,0
NSEL,R,LOC,X,0
NSEL,R,LOC,Z,-(Hs+Hp),Hp
D,all,UX,0,,,,UY,UZ
ALLSEL,ALL
/SOLU
ANTYPE,TRANS
alphad,off
autots,on
KBC,1
*do,i,1,1000
T=i*0.002
acel,0,0,2*sin(20*6.28*T)
NSUBST,1
TINTP,,0.25,0.5,0.5
outres,erase
outres,all,all
SOLVE
*enddo
/POST26
NSOL,2,3579,U,Z,displace !tip位移
DERIV,3,2,1, ,velocity, , ,1, !tip速度
/AXLAB,Y,velocity
PLVAR,3
FINI
/POST26 !电压
NSOL,4,n_top,VOLT,,
!PRVAR,4, !列出时间历程变量结果
NSOL,5,n_bot,VOLT,,
ADD,6,4,5, ,VOLTDROP, , ,1,-1, ,!电阻两端电压差
/AXLAB,Y,OUTPUT POTENTIAL(VOLT)!修改Y轴坐标标签
PLVAR,6 !绘制时间历程变量
FINI
{:{39}:}{:{39}:} {:{03}:} 顶一下吧，搞这方面的大神帮忙解释一下啊 我的问题跟你近乎一样。。。 请问问题解决了么 这貌似是小阻尼结构瞬态部分衰减慢的原因
解决方案:
1 要么把结构阻尼调大(貌似LZ没给结构阻尼)
2 要么把电阻尼调大(就是电阻) 楼主问题解决了吗不知道楼上说的对不对
页:
[1]