ANSYS热应力分析实例
当一个结构加热或冷却时，会发生膨胀或收缩。如果结构各部分之间膨胀收缩程度不同，和结构的膨胀、收缩受到限制，就会产生热应力。7.1热应力分析的分类
ANSYS提供三种进行热应力分析的方法：
在结构应力分析中直接定义节点的温度。如果所以节点的温度已知，则可以通过命令直接定义节点温度。节点温度在应力分析中作为体载荷，而不是节点自由度
间接法。首先进行热分析，然后将求得的节点温度作为体载荷施加在结构应力分析中。
直接法。使用具有温度和位移自由度的耦合单元，同时得到热分析和结构应力分析的结果。
如果节点温度已知，适合第一种方法。但节点温度一般是不知道的。对于大多数问题，推荐使用第二种方法—间接法。因为这种方法可以使用所有热分析的功能和结构分析的功能。如果热分析是瞬态的，只需要找出温度梯度最大的时间点，并将此时间点的节点温度作为荷载施加到结构应力分析中去。如果热和结构的耦合是双向的，即热分析影响结构应力分析，同时结构变形又会影响热分析(如大变形、接触等)，则可以使用第三种直接法—使用耦合单元。此外只有第三种方法可以考虑其他分析领域(电磁、流体等)对热和结构的影响。
7.2间接法进行热应力分析的步骤
首先进行热分析。可以使用热分析的所有功能，包括传导、对流、辐射和表面效应单元等，进行稳态或瞬态热分析。但要注意划分单元时要充分考虑结构分析的要求。例如，在有可能有应力集中的地方的网格要密一些。如果进行瞬态分析，在后处理中要找出热梯度最大的时间点或载荷步。
表7-1热单元及相应的结构单元
热单元结构单元
LINK32LINK1
LINK33LINK8
PLANE35PLANE2
PLANE55PLANE42
SHELL57SHELL63
PLANE67PLANE42
LINK68LINK8
SOLID79SOLID45
MASS71MASS21
PLANE75PLANE25
PLANE77PLANE82
PLANE78PLANE83
PLANE87PLANE92
PLANE90PLANE95
SHELL157SHELL63
重新进入前处理，将热单元转换为相应的结构单元，表7-1是热单元与结构单元的对应表。可以使用菜单进行转换：
Main Menu>Preprocessor>Element Type>Switch Element Type，选择Thermal to Structual。
但要注意设定相应的单元选项。例如热单元的轴对称不能自动转换到结构单元中，需要手工设置一下。在命令流中，可将原热单元的编号重新定义为结构单元，并设置相应的单元选项。
设置结构分析中的材料属性(包括热膨胀系数)以及前处理细节，如节点耦合、约束方程等。
读入热分析中的节点温度，
GUI：Solution>Load Apply>Temperature>From Thermal Analysis。输入或选择热分析的结果文件名*.rth。如果热分析是瞬态的，则还需要输入热梯度最大时的时间点或载荷步。节点温度是作为体载荷施加的，可通过Utility Menu>List>Load>Body Load>On all nodes列表输出。
设置参考温度，Main Menu>Solution>Load Setting>Reference Temp。
进行求解、后处理。
7.3间接法热应力分析实例
7.3.1 问题描述
图7-1冷却栅示意图
热流体在代有冷却栅的管道里流动，如图为其轴对称截面图。管道及冷却栅的材料均为不锈钢，导热系数为1.25Btu/hr-in-oF，弹性模量为28E6lb/in2泊松比为0.3。管内压力为1000 lb/in2，管内流体温度为450 oF，对流系数为1 Btu/hr-in2-oF,外界流体温度为70 oF，对流系数为0.25 Btu/hr-in2-oF。求温度及应力分布。
7.3.2 菜单操作过程
7.3.2.1设置分析标题
1、选择“Utility Menu>File>Change Title”，输入Indirect thermal-stress Analysis of a cooling fin。
2、选择“Utility Menu>File>Change Filename”，输入PIPE_FIN。
7.3.2.2进入热分析，定义热单元和热材料属性
1、选择“Main Menu>Preprocessor>Element Type>Add/Edit/Delete”，选择PLANE55，设定单元选项为轴对称。
2、设定导热系数：选择“Main Menu>Preprocessor>Material Porps>Material Models”，点击Thermal，Conductivity，Isotropic，输入1.25。
7.3.2.3创建模型
1、创建八个关键点，选择“Main Menu>Preprocessor>Creat>Keypoints>On Active CS”，关键点的坐标如下：
编号12345678
X5612126655
Y0000.250.25110.25
2、组成三个面：选择“Main Menu>Preprocessor>Creat>Area>Arbitrary>Throuth Kps”，由1,2,5,8组成面1;由2,3,4,5组成面2;由8,5,6,7组成面3。
3、设定单元尺寸，并划分网格：“Main Menu>Preprocessor>Meshtool”，设定global size为0.125，选择AREA，Mapped，Mesh，点击Pick all。
7.3.2.4施加荷载
1、选择“Utility Menu>Select>Entities>Nodes>By location>X coordinates，From Full”，输入5，点击OK，选择管内壁节点;
2、在管内壁节点上施加对流边界条件：选择“Main Menu>Solution>Apply>Convection>On nodes”，点击Pick，all，输入对流换热系数1，流体环境温度 450。
3、选择“Utility Menu>Select>Entities>Nodes>By location>X coordinates，From Full”，
输入6,12，点击Apply;
4、选择“Utility Menu>Select>Entities>Nodes>By location>Y coordinates，Reselect”，输入0.25,1，点击Apply;
5、选择“Utility Menu>Select>Entities>Nodes>By location>Y coordinates，Also select”，输入12，点击OK;
6、在管外边界上施加对流边界条件：选择“Main Menu>Solution>Apply>Convection>On nodes”，点击Pick，all，输入对流换热系数0.25，流体环境温度70。
7.3.2.5求解
1、选择“Utility Menu>Select>Select Everything”。
2、选择“Main Menu>Solution>Solve Current LS”。
7.3.2.6后处理
1、显示温度分布：选择“Main Menu>General Postproc>Plot Result>Nodal Solution>
Temperature”。
7.3.2.7重新进入前处理，改变单元，定义结构材料
1、选择“Main Menu>Preprocessor>Element Type>Switch Elem Type”,选择Thermal to Structure。
2、选择“Main Menu>Preprocessor>Element Type>Add/Edit/Delete”，点击Option，将结构单元设置为轴对称。
3、选择“Main Menu>Preprocessor>Material Porps>Material Models”，输入材料的EX为28E6，PRXY为0.3，ALPX为0.9E-5。
7.3.2.8定义对称边界条件
1、选择“Utility Menu>Select>Entities>Nodes>By location>Y coordinates，From Full”，
输入0，点击Apply;
2、选择“Utility Menu>Select>Entities>Nodes>By location>Y coordinates，Also select”，输入1，点击Apply;
3、选择“Main Menu>Solution>Apply>Displacement>Symmetry B.C. On Nodes”，点击Pick All，选择Y axis，点击OK;
7.3.2.8施加管内壁压力
1、选择“Utility Menu>Select>Entities>Nodes>By location>X coordinates，From Full”，
输入5，点击OK;
2、选择“Main Menu>Solution>Apply>Pressure>On nodes”，点击Pick All，输入1000。
7.3.2.9设置参考温度
1、选择“Utility Menu>Select>Select Everything”。
2、选择“Main Menu>Solution>-Loads-Setting>Reference Temp”输入70。
7.3.2.10读入热分析结果
1、选择“Main Menu>Solution>Apply>Temperature>From Thermal Analysis>”，选择PIPE_FIN.rth。
7.3.2.11求解
选择“Main Menu>Solution>Solve Current LS”。
7.3.2.12后处理
选择“Main Menu>General Postpro>Plot Result>Nodal Solution>Stress>Von Mises”。
显示等效应力。
7.3.3 等效的命令流方法
/filename,pipe_fin
/TITLE,Thermal-Stress Analysis of a cooling fin
/prep7!进入前处理
et,1,plane55!定义热单元
keyopt,1,3,1!定义轴对称
mp,kxx,1,1.25!定义导热系数
k,1,5!建模
k,2,6
k,3,12
k,4,12,0.25
k,5,6,0.25
k,6,6,1
k,7,5,1
k,8,5,0.25
a,1,2,5,8
a,2,3,4,5
a,8,5,6,7
esize,0.125!定义网格尺寸
amesh,all!划分网格
eplot
finish
/solu!热分析求解
nsel,s,loc,x,5!选择内表面节点
sf,all,conv,1,450!施加对流边界条件
nsel,s,loc,x,6,12!选择外表面节点
nsel,r,loc,y,0.25,1
nsel,a,loc,x,12
sf,all,conv,0.25,70!施加对流边界条件
nsel,all
/pse,conv,hcoef,1
nplot
solve!求解生成PIPE_FIN.rth文件
finish
/post1
plnsol,temp!得到温度场分布
finish
/prep7 !重新进入前处理
etchg,tts!将热单元转换为结构单元
plane42
keyopt,1,3,1!定义轴对称特性
mp,ex,1,28e6!定义弹性模量
mp,nuxy,1,0.3!定义泊松比
mp,alpx,1,0.9e-5!定义热膨胀系数
finish
/solu!进入结构分析求解
nsel,s,loc,y,0!选择对称边界
nsel,a,loc,y,1
dsym,symm,y!定义对称条件
nsel,s,loc,x,5!选择内表面
sf,all,pres,1000!施加压力边界条件
nsel,all
/pbc,all,1
/psf,pres,,1
nplot
tref,70!设定参考温度
ldread,temp,,,,,,rth!读入PIPE_FIN.rth节点温度
/pbc,all,0
/psf,pres,,0分布
/pbf,temp,,1
eplot
solve!求解
finish
/post1,plnsol,s,eqv!得到等效应力
finish
7.4直接法热应力分析实例
7.4.1 问题描述
两个同心圆管之间有一个小间隙，内管中突然流入一种热流体，求经过3分钟后外管表面的温度。已知条件:
管材弹性模量：2E11N/m2
热膨胀系数：5E-41/ oF
泊松比：0.3
导热系数：10W/m.oC
密度：7880Kg/m3
比热：500J/Kg.oC
外管外半径：0.131 m
外管内半径：0.121 m
内管外半径：0.12m
内管内半径：0.11m
流体温度：300oC
流体与内管内壁对流系数：300W/m2.oC
内、外管接触热导：0.1W/oC
7.4.2 命令流方法
/filename,contact_thermal
/title,contact_thermal example
/prep7
et,1,13,4,,1! 选择直接耦合单元PLANE13，单元自由度为ux,uy,temp
! 定义为轴对称
et,2,48! 定义结构接触单元
keyopt,2,1,1! 设定接触单元的相应选项
keyopt,2,2,1
keyopt,2,7,1
r,2,2e11,0,0.0001,,,0.1! 定义接触单元实常数
mp,ex,1,2e11! 定义管材结构及热属性
mp,alpx,1,5e-5
mp,kxx,1,10
mp,dens,1,7880
mp,c,1,500
rect,0.11,0.12,0,0.02! 建模
rect,0.121,0.131,0,0.02
amesh,all
nsel,s,loc,x,0.11! 将内管内壁的X方向位移及温度耦合
cp,1,ux,all
cp,2,temp,all
nsel,s,loc,x,0.12! 将内管外壁的X方向位移及温度耦合
cp,3,ux,all
cp,4,temp,all
nsel,s.loc,x,0.121! 将外管内壁的X方向位移及温度耦合
cp,5,ux,all
cp,6,temp,all
nsel,s,loc,x,0.131! 将外管外壁的X方向位移及温度耦合
cp,7,ux,all
cp,8,temp,all
nsel,s,loc,y,0.02! 将内管顶部节点的Y方向位移及温度耦合
nsel,r,loc,x,0,0.12
cp,9,uy,all
nsel,s,loc,y,0.02! 将外管顶部节点的Y方向位移及温度耦合
nsel,r,loc,x,0.121,0.131
cp,10,uy,all
nsel,s,loc,x,0.12! 创建接触单元
cm,cont,node
nsel,s,loc,x,0.121
cm,targ,node
type,2
real,2
gcgen,cont,targ,3
/solu
antype,trans! 瞬态分析
tunif,20! 初始平均温度
tref,20! 参考温度
sfl,4,conv,300,,300! 内管内壁对流边界
sfl,6,conv,10,,20! 外管外壁对流边界
nsel,s,loc,y,0! 约束所有底边单元的Y向位移
d,all,uy,0
time,180! 载荷步时间
deltime,10,5,15! 定义时间步长
outres,all,all
kbc,1
autots,on! 自动时间步长
allsel
solve! 求解
/post1
plnsol,temp! 显示温度分布
plnsol,s,eqv! 显示等效应力
转自：http://blog.sina.com.cn/s/blog_6a2e0c880101foq3.html
页:
[1]