ansys谐响应分析中F的真面目 时频问题
1111谐响应分析下幅值F=1N，频率f=100Hz
/PREP7
ET,1,SOLID45
MP,EX,1,2E11
MP,PRXY,1,0.3
MP,DENS,1,7800
BLOCK,0,5,0,1,0,1,
ESIZE,1,0,
vmesh,all
nsel,s,loc,x,0
d,all,all
alls
finish
/solu
antype,3
harfrq,100,100
nsubst,1
kbc,0
f,3,fy,1
solve
SET,FIRST
PLNSOL, S,EQV, 0,1.0
显示节点14极小值4.115
2222瞬态动力学分析time从0.0到0.02
载荷F=cos(2*pi*100*time)
pi=acos(-1)
finish
/solu
antype,4
trnopt,full
timint,on
alls
fdele,all,all
*do,i,1,200,
nsubst,1
kbc,0
dt1=i/10000
time,dt1
alls
fdele,all,all
f,3,fy,cos(2*pi*100*dt1)
solve
*enddo
/POST26
NSOL,2,14,S,EQV,SEQV_2
STORE,MERGE
XVAR,1
PLVAR,2,
节点14幅值5.92979
本来是一个方程，Ma+Kx=A*E*（iwt）=A*cos（wt）
幅值应该相同，为何在两种分析下结果不一样？ 一个是频域下的，单频分析，一个是和此频率相对应的瞬态分析，为何差别这么大？？？？
有没有人做过呢？？？？
这是用你的代码算出来的瞬态曲线：响应远未稳定，又怎能拿这个结果和“稳态响应”的结果相比呢？
要想用瞬态方法求出稳态解，必须设置系统阻尼，将由初始条件引起的响应衰减掉。
本帖最后由 Rainyboy 于 2011-8-29 21:56 编辑
另外，谐响应分析中只提取响应的实步子步也是不完善的。应当将SET,1和SET,2的结果都提出出来加以处理。
这些结果与瞬态分析的稳定结果相比，都是相当吻合的，见：
SX：X向正应力
SY：Y向正应力
SZ：Z向正应力
SXY：XY平面内剪应力
SYZ:YZ平面内剪应力
SZX:XZ平面内剪应力
EQV：VON MISES 等效应力
××××××××××××××××××代码×××××××××××××××××××建模
finish
/clear
/CONFIG,NRES,5000
*SET,PI,acos(-1)
*SET,L_FREQ_HZ,100.0
*SET,L_FREQ ,2*PI*L_FREQ_HZ
*SET,N_CIRCLE,100
*SET,NSTP_C,15
*SET,DT,1.0/L_FREQ_HZ/NSTP_C
*SET,AMP,100
/PREP7
ET,1,SOLID45
MP,EX,1,2E11
MP,PRXY,1,0.3
MP,DENS,1,7800
MP,DAMP,1,2*5E-2/L_FREQ
BLOCK,0,5,0,1,0,1,
ESIZE,1,0,
vmesh,all
nsel,s,loc,x,0
d,all,all
alls
finish
瞬态分析
/SOLU
ANTYPE,4 !指定分析类型：动力学分析
TRNOPT,FULL !完全法
TIMINT,ON !时间积分效应
OUTRES,ALL,LAST !所有子步，所有记录写入DATABASE
*DO,I,0,N_CIRCLE-1,1 !外部循环：共计算N_CIRCLE个周期
*DO,J,1,NSTP_C,1 !内部循环：每个周期NSTP_C个载荷步
ALLSEL,ALL
CURR_T=(I*NSTP_C+J)*DT !计算当前载荷步的时间点
F,3,FY,AMP*COS(L_FREQ*CURR_T) !施加当前时间点的载荷
ALLSEL,ALL
TIME,CURR_T !设置当前载荷步的时间点
AUTOTS,1 !自动时间步长
KBC,0 !载荷步之间线性插值：递增方式
DELTIM,DT/10,DT/12,DT/8 !本载荷步之中指定时间步长
LSWRITE,I*NSTP_C+J !写载荷步
*ENDDO
*ENDDO
LSSOLVE,1,N_CIRCLE*NSTP_C !求解所有载荷步
FINISH
谐响应分析
/solu
antype,3
harfrq,100,100
nsubst,1
kbc,0
f,3,fy,AMP
solve
首先感谢Rainboy兄的回帖。一、有阻尼状态下，纠正一下结果（结论是一样的）
谐响应分析处理post26
SX_14
REAL
IMAGINARY
AMPLITUDE
PHASE
36.0269
-52.8163
63.9336
-55.7014
瞬态分析处理
0-0.2s节点14SX0.9-1s结果
二、既然您说阻尼有影响，加上阻尼就可以了。 但是无阻尼呢。
Ma+Kx=F=A*e(i*w*t)=A*cos(w*t)
无阻尼情况下也是一个周期函数吧（《机械振动与噪声学》P98页），只不过稳态的和瞬态的进行叠加：
w<wn，响应以稳态频率运动；
w>wn，响应以瞬态频率运动；
w=wn，出现共振，约等于时出现拍。
那么我在无阻尼时计算的结果应当也是正确的，至少响应的幅值应该差不多吧，可是无阻尼时差别挺大的
回复 6 # superpoliceman 的帖子
无阻尼时响应中还有与激振频率不相等的其他频率成分，若真要对比，至少应该把无阻尼时的响应曲线提出出来做FFT，再比较。 O(∩_∩)O谢谢已作完FFT，结果相吻合，现贴上来，
感谢R兄指教
结果与6楼上述相吻合。
结论：谐响应分析和瞬态分析对同一个问题的分析计算量可能不同，但结果是相同的（FFT变 换即可）；我们在选择分析类型时，按需要即可（一般瞬态分析计算量远远大于谐响应），推荐选择谐响应。
多多交流，大家进步，O(∩_∩)O哈哈~ 回复 4 # Rainyboy 的帖子
想请教下，对于谐响应分析中峰值频率和固有频率不能保持一致，这个问题是怎么回事？
页:
[1]