关于单元类型选择的问题
我建立了一个螺旋桨轴系，想分析其扭转振动，但不知道该用哪种单元类型，怎么约束？有谁能帮帮小弟啊！ 单元的话实体185就行了，轴承处的约束根据轴承的类型而定（径向+轴向/径向），输出端可以全约束，也可以采用弹性约束，即在输出端人为的加弹簧，我做过的一个减速箱扭振分析的例子就采用的这个方法：回复 2 # Rainyboy 的帖子
solid185只有平移自由度，是不是默认的它旋转自由度就不能被约束，我约束是不是加在面上就行？我现在想加一个正弦变化的扭矩怎么加？谢谢了 加在面上也会分配到节点上，要初步模拟轴承对轴的约束，可以在柱坐标系下对相应的节点进行THITA方向（即柱坐标系下的Y自由度）的约束即可。
加扭矩的讨论在ANSYS一度泛滥过，自己检索一下吧。 回复 4 # Rainyboy 的帖子
好的，谢谢了 回复 4 # Rainyboy 的帖子
不过我轴系没考虑轴承的影响，那我想查看自由振动模态分析结果怎么办，没转动自由度啊 回复 6 # geniusfrank2006 的帖子
你是说你现在的计算结果中没有扭转振动的模态是么？ 回复 7 # Rainyboy 的帖子
是啊，你能把你做的命令流什么的传上来么，我学习一下，太感谢了！ 回复 8 # geniusfrank2006 的帖子
命令流没什么特别的，我给你的这个APDL中第一阶就是扭转模态。FINISH
/CLEAR
/PREP7
*SET,R1,45
*SET,R2,50
*SET,R3,180
*SET,R4,185
*SET,L1,300
*SET,L2,30
K,1,0,R1,0
K,2,0,R2,0
K,3,0,R2,L1
K,4,0,R3,L1
K,5,0,R4,L1
K,14,0,R3,L1
K,17,0,R3,L1+L2
K,6,0,R4,L1+L2
K,7,0,R3,L1+L2
K,8,0,R2,L1+L2
K,9,0,R1,L1+L2
K,10,0,R1,L1
L,1,2,1
L,2,3,12
L,3,4,3*2
L,4,7,2
L,7,8,3*2
L,8,9,1
L,9,10,2
L,10,1,12
L,3,10,1
L,3,8,2
L,14,17,2
L,14,5,1
L,5,6,2
L,6,17,1
AL,1,2,8,9
AL,9,10,6,7
AL,3,4,5,10
AL,11,12,13,14
K,100,0,0,0
K,101,0,0,10
VROTAT,ALL,,,,,,100,101,
CSYS,1
LSEL,S,LOC,Z,0
LSEL,A,LOC,Z,L1
LSEL,A,LOC,Z,L1+L2
LESIZE,ALL,,,5
ALLSEL,ALL
ET,1,SOLID186
MP,DENS,1,7.8E-9
MP,PRXY,1,0.3
MP,EX,1,2.1E5
MP,DENS,2,5*7.8E-9
MP,PRXY,2,0.3
MP,EX,2,5*2.1E5
TYPE,1
MAT,1
ALLSEL,ALL
VSEL,S,LOC,Z,0,L1
VMESH,ALL
CSYS,1
TYPE,1
MAT,2
ALLSEL,ALL
VSEL,U,LOC,Z,0,L1
VSEL,R,LOC,X,0,R3/2
VMESH,ALL
TYPE,1
MAT,1
ALLSEL,ALL
VSEL,U,LOC,Z,0,L1
VSEL,U,LOC,X,0,R3/2
VMESH,ALL
NSEL,S,LOC,Z,0
D,ALL,ALL,0
ALLSEL,ALL
NSEL,S,LOC,Z,L1/3,L1*2/3
NSEL,R,LOC,X,R2
NROTAT,ALL
D,ALL,UX,0
ALLSEL,ALL
NSEL,S,LOC,Z,L1+L2
NSEL,R,LOC,X,R1
NROTAT,ALL
F,ALL,FY,1000
ALLSEL,ALL
CSYS,1
NSEL,S,LOC,X,R3
NSEL,R,LOC,Z,L1
CPINF,ALL,
ALLSEL,ALL
!模态
/SOLU
ANTYPE,2 !指定为模态分析
MODOPT,LANB,4 !指定提取特征值数及所用方法
MXPAND,4,,,0 !指定扩展的模态阶数
SOLVE
FINISH
回复 9 # Rainyboy 的帖子
太感谢了，你太热情了，好人啊！ 如果只进行扭转振动分析，强烈建议对模型作一定的简化之后，使用BEAM188进行分析 回复 11 # 409386984 的帖子
谢谢，明白
页:
[1]