自由度耦合一例：梁单元和壳单元的连接
本帖最后由 Rainyboy 于 2011-3-12 12:15 编辑!**********************
!耦合自由度的尝试代码
!范雨2009-4-8
!国际单位制
!**********************
FINISH
/CLEAR
/TITLE,TEST APDL FOR COUPLING
/PREP7
!**********************
!参数表
!**********************
*SET,R_SHELL,0.5!圆柱半径
*SET,L_SHELL,2!圆柱长度
*SET,LN_MESH,32!轴向分网
*SET,RN_MESH,8!周向分网
*SET,TH,0.01!壳单元厚度
*SET,MEX,2.06E11!弹性模量
*SET,MPRXY,0.3!弹性模量
*SET,MDENS,7850!密度
*SET,H_BEAM,0.1!梁界面参数：高
*SET,B_BEAM,0.1!梁界面参数：宽
*set,IZ_BEAM,(B_BEAM)*(H_BEAM**3)/12!绕Z的惯性矩
!**********************
!相关设置
!**********************
!设置材料
MP,EX,1,MEX
MP,PRXY,1,MPRXY
MP,DENS,1,MENDS
!设置壳单元
ET,1,SHELL63
R,1,TH
!设置BEAM单元
ET,2,BEAM3
R,2,H_BEAM*B_BEAM,IZ_BEAM,H_BEAM
!显示SHELL厚度
/ESHAPE,1
!以箭头显示压力
/PSF,PRES,NORM,2,1
!**********************
!柱面->几何->分网
!**********************
M,1
TYPE,1
REAL,1
!建立柱面
K,1,0,0,0
K,2,0,L_SHELL,0
L,1,2
CIRCLE,1,R_SHELL,2
ADRAG,ALL,,,,,,1
LDELE,1
!设置分网数目
ALLSEL,ALL
LSEL,U,LOC,Y,0
LSEL,U,LOC,Y,L_SHELL
LESIZE,ALL,,,LN_MESH
ALLSEL,ALL
LSEL,R,LOC,Y,0
LSEL,A,LOC,Y,L_SHELL
LESIZE,ALL,,,RN_MESH
!对圆柱侧面映射分网
ALLSEL,ALL
ASEL,U,LOC,Y,0
ASEL,U,LOC,Y,L_SHELL
AMESH,ALL
LESIZE,ALL,,,LN_MESH
!**********************
!梁->几何->分网
!**********************
!建立辅助直线
K,100,R_SHELL,0,0
K,101,R_SHELL,L_SHELL,0
L,100,101
K,102,-1*R_SHELL,0,0
K,103,-1*R_SHELL,L_SHELL,0
L,102,103
!设置分网参数
TYPE,2
REAL,2
ALLSEL,ALL
LSLA,U
LESIZE,ALL,,,LN_MESH
!分网
LMESH,ALL
!**********************
!自动耦合自由度
!**********************
ALLSEL,ALL
CPINTF,ALL,0.0001,
!**********************
!两端固支：全约束
!**********************
NSEL,S,LOC,Y,0
NSEL,R,LOC,X,-R_SHELL
D,ALL,ALL,0
NSEL,S,LOC,Y,L_SHELL
NSEL,R,LOC,X,-R_SHELL
D,ALL,ALL,0
!**********************
!加载BEAM上的压力载荷
!**********************
ESEL,S,TYPE,,2
ESEL,R,ELEM,,1025,1056
SFBEAM,ALL,,PRES,-5E5
ALLSEL,ALL
!求解
/SOLU
SOLVE
!后处理
/POST1
PLNSOL,S,EQV,0,,
壳体用SHELL53单元建模，上下有加强的梁，用BEAM3建模，它们之间的在共用节点处一一耦合，通过CPINT命令实现。
网格：
位移解（可以看出耦合自由的效果体现了出来）：
应力解：
恩，命令流很清晰，关键在于耦合自由度那个命令吧，建议用红色标注 回复 2 # mkhatebm 的帖子
恩，这只是当时做的一个尝试。 耦合自由度MPC184约束方程 Rainyboy 发表于 2011-8-18 11:46 static/image/common/back.gif
回复 2 # mkhatebm 的帖子
恩，这只是当时做的一个尝试。
能不能给个详细的GUI操作啊，新手很多看不懂~~跪求，谢谢了 奋斗中中 发表于 2012-12-20 16:11 static/image/common/back.gif
能不能给个详细的GUI操作啊，新手很多看不懂~~跪求，谢谢了
迟早要用APDL的啊，想看GUI的话，可以把在帮助里面找相应的命令，会讲到在哪个菜单里面 Rainyboy 发表于 2012-12-20 22:16 static/image/common/back.gif
迟早要用APDL的啊，想看GUI的话，可以把在帮助里面找相应的命令，会讲到在哪个菜单里面
院长，可不可以给点MPC方面的资料？
比如在一些非协调的时候，如何编辑MPC方程呢？ mxlzhenzhu 发表于 2013-11-5 13:54 static/image/common/back.gif
院长，可不可以给点MPC方面的资料？
比如在一些非协调的时候，如何编辑MPC方程呢？
这方面的了解有限，ANSYS不是有MPC184单元来处理一些常见的耦合吗？
你说的非协调是指？ 同求！院长！
页:
[1]